use POSIX;
 my $y=523.4; 
  printf('%7.2f',floor($y*100/52)/100);
--Output---
  10.06
[download]

In case anyone is wondering why floor() and not int(), it depends on your definition of "rounding" -- int() always rounds towards zero. floor() always rounds down to the next integer that is less than or equal to the number being rounded. This difference is important for negative numbers. E.g.:

$ perl -le 'print int(5.45)'
5

$ perl -le 'print int(-5.45)'  
-5

$ perl -MPOSIX -le 'print floor(5.45)'
5

$ perl -MPOSIX -le 'print floor(-5.45)'
-6
[download]

-xdg

Code posted by xdg on PerlMonks is public domain. It has no warranties, express or implied. Posted code may not have been tested. Use at your own risk.

One way is to just drop the trailing digits:

my $x = $yearlyamount / 52;
$x =~ s/(\.\d\d)\d*$/$1/;
[download]

sprint("%5.2f",$yearlyamount/52 - 0.005)
[download]

For my machine, it will give the wrong answer for any time $yearlyamount equals k * 13, for k at least 9. This is because 52 is 4 * 13, and hence the division by 52 gives the exact answer, and subtracting 0.005 (which cannot be represented exactly in binary) from it causes %f to round it down to the next decimal. For instance, 117 / 52 - 0.005, on my computer with my Perl (5.8.6, with longdoubles and 64bitints) is about 2.244999999999999999895916591441391574335284531116485595703125. Just a tiny, tiny bit below 2.245, but that's enough to give the answer 2.24, instead of 2.25.

Doing arithmetic with reals is very tricky, and it's therefore better to use a good module. POSIX.pm for instance, with its floor method.

Here's another way to approach it:

sub trunc {
    my ($float, $precision) = @_[0..1];
    my @comp = split /\./, $float;
    
    chop $comp[1] while length($comp[1]) > $precision; #trim
    $comp[1].='0' for (length($comp[1])..$precision-1);  #pad
    
    return "$comp[0].$comp[1]";
}

printf ("%5.2f", trunc($yearlyamount/52,2));
[download]

This will, of course, fail utterly if you pass in anything less than pristine values. I leave data validation and error handling as an exercise to whatever masochist chooses this route. Of course, you could also implement it in this insane manner:

$weekly = int(($yearlyamount/52)*100);
$weekly = s,\d{2}$,\.$&,;
printf ("%5.2f", $weekly);
[download]

As a last resort, you could always:

$weekly = sprintf("%.3", $yearlyamount/52);
chop($weekly);
printf "%5.2", $weekly;
[download]

As a last resort, you could always:

weekly = sprintf("%.3", $yearlyamount/52);
chop($weekly);
printf "%5.2", $weekly;
[download]

Except that it will produce wrong values every now and then. It will produce a wrong value whenever $yearlyamount/52 is less than 0.0005 less than a whole number - but still less than said whole number. This causes the "%.3f" rounding to produce a ".000" number, of which the last 0 will be chopped. The final result will be a ".00" number. But it should have been a ".99" number.

use POSIX "floor";

my $yearlyamount = 5199.98;
my $weekly1 = sprintf("%.3f", $yearlyamount/52); 
chop($weekly1);
my $weekly2 = floor(100*5199.98/52)/100;       
printf("%5.2f  %5.2f\n", $weekly1, $weekly2);
__END__
100.00  99.99
[download]