Re^2: How can I populate a hash?

You can do it without an explicit loop if you're sick enough to try:

#!/usr/bin/perl

use strict;
use warnings;

use Test::More tests => 3;

package CountHash;

sub TIEHASH
{
    my $class = shift;
    bless {}, $class;
}

sub FETCH
{
    my ($self, $key) = @_;
    return unless exists $self->{$key};
    return               $self->{$key};
}

sub STORE
{
    my ($self, $key, $value) = @_;
    ($self->{$key} ||= 0 )++;
}

sub FIRSTKEY
{
    my $self  = shift;
    my $first = keys %$self;
    each %$self;
}

sub NEXTKEY
{
    my $self = shift;
    each %$self;
}

package main;

tie my %hash, 'CountHash';
my @items = ( 1, 2, 3, 3, 3, 4, 5, 5, 5, 5 );
@hash{ @items } = ();
is( keys %hash, 5, 'CountHash should not store duplicate keys' );
is( $hash{1},   1, '... counting individual keys once' );
is( $hash{3},   3, '... multiple keys multiple times' );
[download]

Comment on Re^2: How can I populate a hash? Download Code

Replies are listed 'Best First'.
Re^3: How can I populate a hash? by Aristotle (Chancellor) on Jan 26, 2005 at 02:25 UTC
Hmm. It occurs to me that if the goal's to do it in a single statement, it can be done quite easily: `#!/usr/bin/perl use strict; use warnings; my @k = qw( a b c a b a ); my %i = do { my %h; map { $_ => ++$h{$_} } @k }; print join " ", %i;` [download] That's cheating of course, but so is tie. `:-)` Makeshifts last the longest.	[reply] [d/l]