• quotemeta, using "\Q" inside the regex (see also perlop), to search for literal substrings instead of a pattern
• Do not put extra quotes in your substitution pattern, it'll cause it to fail
• There's no need to match and substitute in two steps. s/// will just return a true flag if it indeed did substitute anything, and do nothing otherwise
• Anchor the match to the beginning of the string, using ^, or you'll allow it to substitute anywhere in the string — unless that's what you want?

The resulting code is:

if($folder_path =~ s/^\Q$sourcedir/Eitv9/) {
            print "\n$folder_path/$file";}
[download]

Oh and if the path comes from the user using STDIN, don't forget to chomp it first.

Thanks bart !
it worked , even before posting i tried what boris had suggested but that lead to a failure why ?
prad

The difference is in my use of quotemeta, \Q inside the regex. His version uses your string as a regex, mine turns it into a literal search.

Here is a simple demo for what's going on:

my $string = 'c:\\Windows';
my $search = '\\W';
my $qm = quotemeta($search);
my $raw = $string; $raw=~ s/$search/#/;
my $cooked = $string; $cooked =~ s/\Q$search/#/;
print <<"TEST"
original string: '$string'
search string: '$search'
search string after quotemeta: '$qm'
substitution without \\Q: '$raw'
substitution with \\Q: '$cooked'
TEST
[download]

Result:

original string: 'c:\Windows'
search string: '\W'
search string after quotemeta: '\\W'
substitution without \Q: 'c#\Windows'
substitution with \Q: 'c:#indows'

As you can see, with quotemeta, it replaced the substring backslash+"W", because that's what /\\W/ searches for. Without it, it just searched for the first non-word character and replaced it — that happens to be a ":".

Hi just try this,

$folder_path =~ s#^\Q$sourcedir\E#Eitv9#i
[download]

use strict;
use warnings;

#sourcedir, as it comes from <STDIN>, hence it has a newline
my $sourcedir   = 'C:\Documents and Settings\Administrator\Desktop\eit
+v9_lvttest' . "\n";
my $folder_path = 'C:\Documents and Settings\Administrator\Desktop\eit
+v9_lvttest';
my $file = "test";

#get rid of newline
chomp $sourcedir;

#escape backslashes and other possible regex-affecting meta-characters
my $sourcedir_regex = quotemeta($sourcedir);


if( $folder_path =~ s/$sourcedir_regex/Eitv9/ )
{
    print "\n$folder_path/$file";
}
[download]

$source_path = 'C:\Documents and Settings\Administrator\Desktop\';
## Note the single quotes

$folder_path =  'C:\Documents and Settings\Administrator\Desktop\eitv9
+_lvttest';
## Replace: remember to escape your '\', and to replace case-insensiti
+vely.
$folder_path =~ s[^$source_path][Eitv9\\]i;
[download]

$folder_path=~s/$sourcedir/Eitv9/;
[download]

that won´t work, because of the backslashes in $sourcestring. They must be escaped.

holli, regexed monk

To be honest, I stopped using regexp's for this a while ago. I use substr now:

if ($folder_path =~ /^$sourcedir/) {
  $folder_path = File::Spec->catdir('Eitv9',substr($folder_path, lengt
+h $source_dir));
}
[download]

$folder_path =~ s/^\Q$sourcedir/Eitv9/;
[download]

use File::Basename;

print 'Evit9/' . basename( $folder_path );
[download]