Thanks!! i just did that
it ended up like this:


use strict;

my @codesref = undef;

$codesref[0] = sub {print "SUB 1\n";};
$codesref[1] = sub {print "SUB 2\n";};
foreach my $code (@codesref){
    $code->();
}
[download]

and it worked just fine


ignorance, the plague is everywhere
--guttermouth

More idiomatic and a bit less syntax:

my @codesref;
push @codesref, sub { print "SUB 1\n" };
push @codesref, sub { print "SUB 2\n" };
$_->() for @codesref;
[download]

Concatenation is for strings. You need to make a copy of the first coderef and make a new coderef that calls the copy. Note that the copy stays around, even though it's gone out of scope, because the new one creates a closure around it. Here's an example:

my $code = sub {
    print "Sub 1";
};

$code = do {
    my $oldcode = $code;
    sub {
        $oldcode->();
        print "Sub 2";
    };
};

$code->();
[download]

Update: this do block could be further generalized into a subroutine, but that's an exercise left to the reader. :-)

Update: phaylon's solution is much simpler, and the OP seems happy with it, but the closure technique I've shown is a way to get both [or as many as necessary] to execute from a single starting point, [update] and without a loop at all :-P

Sub, schmub. Overload is your (evil) friend . . .

Update: Of course for efficiency you might want to check if UNIVERSAL::isa( $other, "CatCode" ) and pull out its coderef from $other->{_code}.

Update: Another tweak. To paraphrase Homer Simpson, "In America first joo geet dee syntactic shoooogar, dehn joo geet dee powah, dehn joo geet de wimin."

Update: And even more silliness, buscc that reverses the call order (new code called first then the old code).

#!/usr/bin/perl
BEGIN {
## This would really be in CatCode.pm . . .
package CatCode;

use UNIVERSAL qw( isa );
use overload "." => "_cat_sub",
             "&{}" => "_call_sub";

require Exporter;
@CatCode::ISA = qw( Exporter );
@CatCode::EXPORT_OK = qw( ccsub );

sub ccsub (&) { return CatCode->new( shift() ); }

sub new {
  my $class = shift;    
  my $code = shift;

  return bless { _code => $code }, $class;
}

sub _cat_sub {
  my( $self, $other ) = @_;

  my $oldcode = $self->{_code};

  if( isa( $other, "CatCode::Reverse" ) ) {
    $other = $other->{_code};
    $self->{_code} = sub { $other->( @_ ); $oldcode->( @_ ); };
  } elsif( isa( $other, "CatCode" ) ) {
    $other = $other->{_code};
    $self->{_code} = sub { $oldcode->( @_ ); $other->( @_ ) };
  } else {
    $self->{_code} = sub { $oldcode->( @_ ); $other->( @_ ) };
  }

  return $self;
}

sub _call_sub { my $self = shift; sub { $self->{_code}->( @_ ) } }

package CatCode::Reverse;

@CatCode::Reverse::ISA = qw( CatCode );
@CatCode::Reverse::EXPORT_OK = qw( buscc );

sub buscc (&) { CatCode::Reverse->new( shift() ); }

1;

}

package main;

BEGIN { CatCode->import( qw( ccsub ) )}
BEGIN { CatCode::Reverse->import( qw( buscc ) )}

my $cc = ccsub { print "one $_[0]\n" };

$cc .= sub { print "two $_[0]\n" };

$cc .= buscc { print "three $_[0]\n" };

$cc .= sub { print "four $_[0]\n" };

$cc->( "fish" );

exit 0

__END__
[download]

If you overrode _cat_sub in CatCode::Reverse, you could replace the conditional with polymorphism and wouldn't have to use the polymorphism-hostile direct UNIVERSAL::isa call.

Using an array is the right solution but this works.

my $code = sub {print "Sub 1\n"};
$code = joincoderefs( $code, sub {print "Sub 2\n"});
&$code;
sub joincoderefs {
    my @refs = @_;
    return sub { $_->() for @refs };
}
[download]

outputs:

Sub 1
Sub 2
[download]

--

flounder

Using an array is the right solution

I agree that an array of coderefs seems to be the best solution, in this case. Especially since the OP has already responded, saying that the array works. But I still think it's useful to show other techniques -- such as you have done -- which may be more appropriate in other situations. Talking about which one is the "right solution" is a different discussion altogether.

to execute from a single starting point.

Just put the loop in a sub, there ya go :D

$ perl -w
sub addcoderef { my ($orig, $add) = @_; sub { $orig->(); $add->(); } }
use strict;
my $coderef = sub { print "SUB1\n"; };
$coderef = addcoderef( $coderef, sub { print "SUB2\n"; } );
$coderef->();
__END__
SUB1
SUB2
[download]

Another option is to deparse them (but deparsing historically hasn't worked 100%):

$ perl -w
use strict;
sub addcoderef {
   use B::Deparse;
   my $d = B::Deparse->new();
   eval join "\n", "sub {", map($d->coderef2text($_), @_), "}";
}
my $coderef = sub { print "SUB1\n"; };
$coderef = addcoderef( $coderef, sub { print "SUB2\n"; } );
$coderef->();
__END__
SUB1
SUB2
[download]

#! perl -l

my $f = sub { "f($_[0])" };
my $g = sub { "g($_[0])" };

print $f->("x");
# f(x)
print $g->("x");
# g(x)
[download]

sub compose2 {
    my ($f, $g) = @_;
    sub { $f->( $g->(@_) ) }
}
[download]

my $h = compose2( $f, $g );
print $h->("x");
# f(g(x))
[download]

sub foldl {
    my $f = shift;
    my $z = shift;
    $z = $f->($z, $_) for @_;
    $z;
}

sub compose {
    foldl( \&compose2, @_ )
}
[download]

print compose( $f,$f,$f,$f,$f,$f,$g )->("x");
# f(f(f(f(f(f(g(x)))))))

my $add1 = sub { $_[0] + 1 };
my $add2 = compose( $add1, $add1 );
my $add4 = compose( $add2, $add2 );

print $add2->(0);
# 2

print $add4->(0);
# 4

print compose( $add1, $add1, $add1 )->(0);
# 3

print compose( ($add1) x 4 )->(0);
# 4
[download]

Cheers,
Tom