use My::Module @args;

# This becomes ...

BEGIN {
    require My::Module;
    My::Module->import( @args );
}
[download]

require is approximately the following code:

require My::Module;

# This becomes ...

sub require {
    my ($name) = @_;

    (my $filename = $name) =~ s!::!/!g;
    $filename .= '.pm' if $name =~ /::/;

    unless ( exists $INC{ $filename } ) {
        # Load the file into memory, figuring out which of @INC to use
+.
        # Put the full pathname into $full_path_name
        $INC{ $filename } = $full_path_name;
    }
}
[download]

So, if a module has already been loaded, it won't be loaded again, but its import() will be called again (as tye noted in the original thread).

Your confusion is arising because you're attempting to load File::BaseName and File::Basename on case-insensitive operating system. Because it's case-insensitive, the check against %INC is subverted. On case-insensitive operating systems, the following version of require may be more appropriate:

sub require {
    my ($name) = @_;

########## THIS IS ADDED
    $name = lc $name;
########## TO HERE

    (my $filename = $name) =~ s!::!/!g;
    $filename .= '.pm' if $name =~ /::/;

    unless ( exists $INC{ $filename } ) {
        # Load the file into memory, figuring out which of @INC to use
+.
        # Put the full pathname into $full_path_name
        $INC{ $filename } = $full_path_name;
    }
}
[download]

That should appropriately fix things. (But, it won't catch things like use Strict; - that lc fix would have to be part of use, which may not be a bad thing.)

That should appropriately fix things.

Will it? Sure, you don't get warnings if you do:

use File::Basename;
use File::BaseName;
[download]

as the second use will not do anything. But if you remove the first one, or if you swap the two statements, File::Basename->import() won't be called, as Perl will try to call File::BaseName->import(), which doesn't exists so Perl will silently go on.

This will lead to mysterious behaviour, that may be hard to debug.

File::Basename->import() won't be called, as Perl will try to call File::BaseName->import(), which doesn't exists so Perl will silently go on

You're describing the current behavior. His change, whatever other implications it may have, would not affect that.

Update: to clarify my statement for Anonymous Monk, I meant that adding the lc $name doesn't change whether use File::BaseName would call the right import routine, or not.

I thought his question was why do the warnings go away when you add () to one of the use statments. I'm not sure how your answer answers that.


___________
Eric Hodges

Because calling 'use File::Basename();' tells the compiler to import an empty list -- in other words, do not import anything. The issue at hand is that File::Basename and File::Basename are both trying to import subroutines into the main:: namespace by default.

Be well,
rir

--
Here's a nickel, kid, get yourself a real filesystem. And keep the change.

The fact that you're referring to Win32 (and VMS) as a degenerate case is absolutely delicious. ++!

Being right, does not endow the right to be rude; politeness costs nothing.
Being unknowing, is not the same as being stupid.
Expressing a contrary opinion, whether to the individual or the group, is more often a sign of deeper thought than of cantankerous belligerence.
Do not mistake your goals as the only goals; your opinion as the only opinion; your confidence as correctness. Saying you know better is not the same as explaining you know better.

I presume this is a warning to prevent incompatible modules being used at the same time?

For example

one.pm

#!/usr/bin/perl -w
use strict;
package one;
require Exporter;
our @ISA = ("Exporter");
our @EXPORT = qw(foo);
sub foo {
    print "how do you do\n";
}
[download]

#!/usr/bin/perl -w
use strict;
package two;
require Exporter;
our @ISA = ("Exporter");
our @EXPORT = qw(foo);
sub foo {
    print "Salut toi! Ca va?\n";
}
[download]

#!/usr/bin/perl -w
use strict;
use one;
use two;
foo();
[download]

[~/] perl trial.pl 
Subroutine main::foo redefined at /usr/local/lib/perl5/5.8.2/Exporter.
+pm line 60.
 at trial.pl line 4
Salut toi! Ca va?
[download]

modified trial.pl

#!/usr/bin/perl -w
use strict;
use two;
use one;
foo();
[download]

[~/] perl trial.pl
Subroutine main::foo redefined at /usr/local/lib/perl5/5.8.2/Exporter.
+pm line 60.
 at trial.pl line 4
how do you do
[download]