Is this magic enough for you?

#!/usr/bin/perl -w
# test.pl --
use strict;
use warnings;
use diagnostics;

my @a = qw( one two three );

print join( "\n", @a ), "\n__________\n";
setmode( 'add_test', \@a );
print join( "\n", @a );

sub setmode {
    my $val = shift;
    splice( @{$_[0]}, 1, 0, $val );
}
[download]

You possibly want the \@ prototype which will give you a reference to an array when you give a literal array name as that parameter. See the section on "Prototypes" in perldoc perlsub.

As Fletch suggested, a prototype will work in this situation:

#!/usr/bin/perl -w

use strict;

sub setmode ($\@) {
    my $val = shift;
    splice(@{$_[0]}, 1, 0, $val);
}

my @a = qw(one two three);

print join($/, @a), "$/__________$/";
setmode('add_test', @a);
print join($/, @a), $/;

__END__
result:

one
two
three
__________
one
add_test
two
three
[download]

You can have your cake and eat it too :)

Use a prototype to avoid the backslash and assign the reference to a localised glob to avoid teh need to dereference in the sub.

#! perl -sw
use strict;

sub setmode ($\@) { ## the prototype makes the reference
    our @array;                ## satisfy strict
    my $val = shift;
    local *array = shift;      ## alias the reference 
    splice @array, 1, 0, $val; ## do normal array operations
}

my @a = qw( one two three );

print join( "\n", @a ), "\n__________\n";
setmode 'add_test', @a;
print join( "\n", @a );

__END__
[ 7:19:41.56] P:\test>junk3
one
two
three
__________
one
add_test
two
three
[download]

Whether the effort is worth may depend upon how much dereferencing you will do in the sub, and possibly whether the elements of the array might need further dereferencing.

Whether using prototypes, our and local is acceptable will depend upon your personal or corporate "acceptably unconfusing and mainatainable subset" of Perl's facilities and syntax.

---

Examine what is said, not who speaks.

Silence betokens consent.

Love the truth but pardon error.

A better grade of magic here. This is closer to what I was hoping for when I asked the question. Must be all that 'tolkien' in the air. My own preference would be for local and since I am both the 'personal' and the 'corporate' in this context it's a win no matter how I do it. Life is nice when you work for yourself---now if there were only money in it!??! Thanks BrowserUk

Update:
I note that this:

sub setmode ($\@) {
    our (@array,$val);
    ($val,*array) = @_;
    splice (@array, 1, 0, $val);
}
[download]

works as well.

--hsm

"Never try to teach a pig to sing...it wastes your time and it annoys the pig."

This won't work in perl 6, though, will it?

In answer to my recent post Trying to understand aliasing (*var), dave_the_m wrote

"Typeglobs, ie *foo are mostly an artifact of Perl 4, which didn't have references; they will be removed completely in Perl6"

So that might be a reason to avoid this particular type of magic, and stick with a slash type \$reference.

This is just plain bad and evil and it doesn't buy you anything--rather the opposite--but TMTOWTDI and it uses what many would call "magic":

{
    local *_ = \@a;
    unshift @_, 'add_test';
    &setmode;
}
[download]

ihb