There are a couple of ways to go from a variable name in a string to its value, and they are both pretty evil.

You could try it with a soft reference, which is bad enough that it has its own little area in the strict module.

#!/usr/bin/perl

@array1 = qw( a b c );
@array2 = qw( x y z );
@array3 = qw( 3 9 6 );

while (<DATA>){
        chomp;
        no strict refs;
        s/^@//;
        print "@{$_}\n";
        }
[download]

You could do it with the string form of eval(), but then you have to make sure you have something safe in the string you are about to eval. Someone could sneak something into the input and execute it as perl code (not good).

#!/usr/bin/perl

@array1 = qw( a b c );
@array2 = qw( x y z );
@array3 = qw( 3 9 6 );

while (<DATA>){
        eval qq|print "$_"|;
        }
[download]

You can also create a jump table so you can look up the value in a hash. You use the input string as the hash key. If the input value is not a key in the hash, nothing bad happens.

#!/usr/bin/perl

@array1 = qw( a b c );
@array2 = qw( x y z );
@array3 = qw( 3 9 6 );

my %hash = (
    '@array1' => \@array1,
    '@array2' => \@array2,
    '@array3' => \@array3,
    );

while (<DATA>){
        chomp;
        print "@{ $hash{$_} }\n";
        }

__DATA__
@array1
@array2
@array3
[download]