You're doing the counts just right (but you may want to translate punctuation before splitting). You only need to manipulate the hash a bit to get what you want. Taking keys of the hash will give you the list of distinct words, which can be sorted by their value in %count:

my @wordlist = sort {$count{$b} <=> $count{$a}} keys %count;
print 'The text contains ', scalar(@wordlist), ' distinct words', "\n"
+;
print "$_\t$count{$_}\n" for @wordlist;
[download]

• parsing the file line by line, instead of slurping the entire file and splitting it in a array
• define what a 'word' is: does case matter? are punctuations/numers allowed?

assuming that case doesn't matter and words are defined by </code>\w+</code>, this code should work:

my %count;
while ( <FILE> ) {
    $count{lc $_}++ for /\w+/g;
}

print "$_ => $count{$_}\n"
    for sort { $count{$b} <=> $count{$a} || $a cmp $b} keys %count;
[download]

HTH,
Paul

Hi perl_seeker

This should do what you want

for (sort {$count{$b} <=> $count{$a}} keys %count){
     print "$_ $count{$_}\n";
};
[download]

thinker

Hello!
"my apologies to everyone for the delayed response."
Thanks for the code thinker, works fine.
perl_seeker:)

my $total_words = @words; #All word count
my %count;
$count{$_}++ for @words; # Here are the counts
my $uniq_words  = scalar keys %count; # Nš of uniq words

# Print sorted by frequency

print "$_\t$count{$_}" for (sort { $count{$b} <=> $count{$a} } keys %c
+ount);
[download]

Hope it helps,
deibyz

EDIT: I wasn't accounting for extra spaces on the start, end or middle of each line. Updated code and added comments.

EDIT: Also updated so comments fit properly.

use strict;
use warnings;

my (%count, $last);
my $max = 0;

while (<DATA>) {
    s/^ +//; s/\s+$//; s/  +/ /g;  ## Remove extra spaces
    $_ = lc($_);                   ## Lowercase so not sensitive
    $_ = $last . $_;               ## Append word piece
    if (m/-$/) {                   ## If line ends in -, remove last
        ($_, $last) = m/(.*?) ?(\w+)-/; ## word piece for appending
    } else { $last = ''; }         ## Else word piece is nothing
    s/[^\w' ]//g;                  ## Remove extra punctuation
    s/(\w)'(\w)/$1-$2/g;           ## Convert ' inside words to -
    s/'//g;                        ## Remove all remaining '
    s/-/'/g;                       ## Convert - back to '
    for (split / +/) {             ## Split on space and
        $count{$_}++;              ## process words
        $max = length() if length() > $max; ## Find longest word size
    }
}

print sprintf('%'.$max.'s', $_) . " => $count{$_}\n"
    for sort { $count{$b} <=> $count{$a} || $a cmp $b} keys %count;

__DATA__
I can't be bought, and I won't be bought! My school-
house is my own, my precious. One school to rule them
all! This is my cant, my creed.
 Funky  space  check!
[download]

Hello Ted,
thanks for the code and your ideas. I am actually working with text in a font for another language
(not English), so the tokenisation and translation code does not work for me, but of course works
great with your test data in English. But anyway, got the idea.

In this font, a single letter(vowel/consonant), may be mapped to two or more ascii characters, e.g.

letter 1 in my font =  ascii chars sd
letter 2 in my font =  ascii chars !#
[download]

Though of course we can do the frequency count of words from %count, and also find the no of unique words from it;we are still building %count from an array into which the words have been pushed.
Right now this works, but if the array were to hold a huge number of words, say 1 million,would this not be a problem? Is there a way around this?
Thanks,
perl_seeker:)