Perhaps a Super Search would have helped Finding longest palindrome from a string

Cheers,
R.

my $re;
$re = qr/((.)(??{ $re })\2|.)/;
my $s = 'abcdegedfc';
foreach my $i (0 .. length($s) - 1) {
    local $\ = "\n";  # add newline to print
    substr($s, $i) =~ /^$re/ and print $1;
}
[download]

This little program prints:

a
b
c
deged
ege
g
e
d
f
c

update: I found a second working regex, inspired by holli who came up with the idea to use reverse:

my $s = 'abcdegedfc';
foreach my $i (0 .. length($s) - 1) {
    local $\ = "\n";  # add newline to print
    substr($s, $i) =~ /((.*).?(??{ quotemeta reverse $2 }))/
      and print $1;
}
[download]

Your delayed-evaluation expression isn't quite right. It won't match palindromes like 'feef' that don't have a central character. You need to make the single dot optional. And if you put the alternation in the middle, you won't match one-character "palindromes".

You can also simplify your search by putting the pattern in a lookahead and doing a while-global match:

$_ = 'abcdegedfc'; # Try it without the g, too.
my $re;
$re = qr/((.)(?:(??{$re})|.?)\2)/;
print "$1\n" while (/(?=$re)/g);
[download]

If you change the * to a + in the reverse version, you exclude single-character palindromes. The lookahead while-global trick helps here, too:

$_ = 'abcdegedfc';
print "$1\n" while (/(?=((.+).?(??{quotemeta reverse $2})))/g);
[download]

---

Caution: Contents may have been coded under pressure.

Your delayed-evaluation expression isn't quite right. It won't match palindromes like 'feef' that don't have a central character. You need to make the single dot optional.

You're right. I knew that, and I still forgot about it. Thanks for the correction.

Sorry, but put like that it really sounds like homework....
Why the restriction?

The base regexp for a potential midpoint is /(.).?\1/. The problem is that a single piece of input may contain multiple palindromic fragments in a larger palindrome. You will therefore need to test all midpoints.

The code below creates a series of regular expressions that increasingly match longer palindromes.

#! /usr/bin/perl -w

use strict;
use warnings;

my $data = shift;

$data =~ s/\W//g;

my @groups;
my @refs;

for (1 .. (length $data) / 2)
{
    push @groups, "(.)";
    unshift @refs, "\\$_";
    my $regex = join('',@groups).".?".join('',@refs);
    print "$regex\n";
    while ($data =~ /$regex/ig)
    {
        print "$&\n";
    }
}
[download]

The above code needs to run within the limits of the total number of matches that are available in the Perl regex engine.

This regular expression looks simpler but uses in pattern code execution which is not supported across all regex engines (but it is in Perl so you will be OK). /(.*).?(?{reverse($1)})/.

A hybrid approach would be to locate the midpoint using the /(.).?\1/ regex and then compare the leading part and the reverse of the trailing parts.

use Regexp::Common;
s/.*?($RE{lingua}{palindrome}).*/$1/s;
[download]

For me, it always matches one character; it never matches a nontrivial palindrome.

use Regexp::Common;
$_ = 'abcdegedfc';
while (/($RE{lingua}{palindrome})/g) {
  print "Got $1\n";
}
__END__
Got a
Got b
Got c
Got d
Got e
Got g
Got e
Got d
Got f
Got c
[download]

---

Caution: Contents may have been coded under pressure.