Weird, works for me:

>perl -e "eval { require Boo }; print """[$@]""" if $@;"
[Can't locate Boo.pm in @INC (@INC contains: ...) at -e line 1.
]
[download]

Remember that require doesn't call import like use does, so you need to call it explicitly:

use Module;
  |
  v
require Module;
Module->import() if Module->can('import');


use Module qw(a b);
  |
  v
require Module;
Module->import(qw(a b)) if Module->can('import');


use Module ();
  |
  v
require Module;
[download]

So...

unless( eval { require module; 1 } ) {
  my $err = $@ || 'eval failed but did not return error';
  # do something with $err
}
[download]

Many months later I now know how eval{} can fail and yet not set $@. It happens if a DESTROY method called during the stack-unwind also does an eval.

use AtExit;

eval {
    my $q = AtExit->new(sub{eval{}});
    die "Oops\n";
};

print $@; # Prints nothing
[download]

Which means you have to

sub DESTROY{
 local $@;
 eval{...}
}
[download]

if you want to use eval in DESTROY.

Try:

eval { require Foobar } or die "Where's Foobar? ($@)\n";
[download]