s/b/c/g is not a regexp, it's a Perl expression. Only the b of s/b/c/g is a regexp.

eval is provided to execute Perl expressions:

$a = "aaabbbaaa";
$b = "s/b/c/g";
eval '$a =~ ' . $b;
[download]

or

local $_ = "aaabbbaaa";
$b = "s/b/c/g";
eval $b;
[download]

Unfortunately, eval EXPR can be used to execute any Perl expressions, even calls to system, for example. It would be safer if you were provided the regexp and the substitution parts seperately, as I mentioned in this node:

# Inputs
# ======

$string = "aaabbbaaa";
$regexp = "b";
$subst  = "c";
$global = 1;

# (?i...) can be used in $regexp for /.../i
# (?m...) can be used in $regexp for /.../m
# (?s...) can be used in $regexp for /.../s
# (?x...) can be used in $regexp for /.../x
# /g cannot be stored in $regexp, thus the need for $global.
# /e cannot be stored in $regexp, but I'm not supporting it.

# Guts
# ====

# Check user input.
eval {
   # Let's explicitely be on the safe side.
   no re 'eval'; 
   $regexp = qr/$regexp/;
};

# Handle bad user input.
die("Bad regexp supplied: $@\n") if $@;

# Do the work.
if ($global) {
   $string =~ s/$regexp/$subst/g;
} else {
   $string =~ s/$regexp/$subst/;
}
[download]

Known bugs: People mentioned that this does not provide a means of using $1, $2, etc in $subst.

Something like this:

my $c = 'aaabbbaaa';
my $d = 's/b/c/g';
eval "\$c =~ $d";
die "Failure: $@\n" if $@;
print $c, "\n";
[download]

Depending on where your $d is coming from, this could expose you to code injection. Be cautious.

Also notice I refrained from using $a and $b. This is usually a good idea, as the use of $a and $b can get confusing since sort uses special global versions of $a and $b also.