#!perl -w
use strict;
use Text::CSV_XS;
use IO::File;
my $csv   = Text::CSV_XS->new( {binary=>1} );
my $fh    = IO::File->new('myfile.csv');
my $count = 0;
while (my $cols = $csv->getline($fh)) {
    last unless @$cols;
    print ++$count . ". @$cols\n";
}
[download]

#!perl -w
use strict;
use DBI;
my $dbh=DBI->connect("dbi:CSV(RaiseError=1):csv_eol=\n");
$dbh->{csv_tables}->{tbl1}->{file}='tmp.csv';
$dbh->{csv_tables}->{tbl2}->{file}='tmp2.csv';
$dbh->{csv_tables}->{tbl3}->{file}='combined.csv';
$dbh->do("CREATE TABLE tbl3 AS SELECT * FROM tbl1 NATURAL JOIN tbl2");
[download]

getline parses a single line, but if you want to keep the original lines (so that you can determine the lines that appear in both files), then I don't think it is very useful to you. How about this (untested!)?:

use strict;
use warnings;

use Text::CSV_XS;

my ( $h1, $h2 ) = map get_parsed_lines( $_ ), qw( file_1 file_2 );

my %keep =
  map +( $_ => $h1->{ $_ } ),
  grep exists $h2->{ $_ },
  keys %$h1;

sub get_parsed_lines {
  my $file = shift;
  my $csv = Text::CSV_XS->new();
  my %hash;
  open my $in, '<', $file or die "Read failed: $!\n";
  while ( <$in> ) {
    $csv->parse( $_ ) or warn "Bad data: $_\n", next;
    $hash{ $_ } = [ $csv->fields() ];
  }
  close $in or die "Failed to close $file: $!\n";
  return \%hash;
}
[download]

Thankyou for your solution and it works up until some of the information from the 2 tables is different for same entry. So, say I have 1 person and part of the CSV is the date they posted something. One date was 4/25/2005 and another is 5/1/2005 I still only want to have 1 copy of this person in the combined CSV file. Since the solution puts everything into the Keys of the hash this causes a problem. I was wondering if there was an easy way to just get 1 of the fields of the csv file as the key to the has and put all of the information into the value? I hope that makes sense.

Sure, that would very easy. Suppose you wanted to use the third field as hashkey. Then get_parsed_lines would be changed to:

sub get_parsed_lines {
  my $file = shift;
  my $csv = Text::CSV_XS->new();
  my %hash;
  open my $in, '<', $file or die "Read failed: $!\n";
  while ( <$in> ) {
    $csv->parse( $_ ) or warn "Bad data: $_\n", next;
    my @row = $csv->fields();
    $hash{ $row[ 2 ] } = \@row;
  }
  close $in or die "Failed to close $file: $!\n";
  return \%hash;
}
[download]

More generally, you may want to use several fields, e.g., fields 0, 2 and 3. In this case, just change the last line in the loop to

    $hash{ join( ',', @row[ 0, 2, 3] ) } = \@row;
[download]

the lowliest monk

Looks to me like you really don't need CSV at all, but you need Text::Diff. Or, if you do need to do some mangling to the CSV, maybe Algorithm::Diff would be of help?

That was my first thought also (that the OP doesn't really need CSV parsing), but a) two CSV tables can contain identical rows in different orders so a diff approach may not work, b) fields may contain embedded newlines so a line-oriented approach may not work, c) if requirements change and the comparison is done on key fields rather than whole records, the CSV approach will scale up.

See perlreftut. Here's the basics:

my $cols_arrayref = $csv->getline($fh);  # get an arrayref
my @cols_array = @$cols_arrayref;        # deref the entire array
my $col = $cols_arrayref->[0];           # or deref an element
[download]