Yet another way, using List::Compare:

use strict;
use warnings;
use List::Compare;

my @a = (1, 2, 3, 4, 5, 6);
my @b = ( 3, 4 , 5, 6, 7, 8);

my $lc = List::Compare->new( \@a, \@b );

my @a_only = $lc->get_Lonly;
my @b_only = $lc->get_Ronly;

print join( ', ', @a_only ), "\n"; # 1, 2
print join( ', ', @b_only ), "\n"; # 7, 8
[download]

This type of question is asked frequently. You can SuperSearch for other threads, such as most efficient way to implement "A without B", and search CPAN for modules in the List:: namespace.

HTH

my %in_a;
@in_a{ @a } = (1) x @a;
my @only_b = grep !exists $in_a{ $_ }, @b;
[download]

Try this:

my @a = ( 1, 2, 3, 4, 5, 6 );
my @b = ( 3, 4, 5, 6, 7, 8 );
my %a_lookup;
@a_lookup{@a} = ();
my @b_only = grep { not exists $a_lookup{$_} } @b;
print "@b_only\n";
[download]

If my calculations are correct, this ought to do the trick. ;)

Update: Whenever I see a question like this I think to myself, "That sounds like something Quantum::Superpositions could do with grace and ease. While it's true that the Damian's module does accomplish this task simply and easily, it took a conversation in the Chatterbox with tye and merlyn before the actual solution became apparent to me. Credit merlyn for coming up with the Quantum::Superpositions solution at first guess... for my part, I just started the conversation rolling until an expert could come along and get it right. ;)

use Quantum::Superpositions;

my @a = ( 1 .. 6 );
my @b = ( 3 .. 8 );
print "$_\n" foreach eigenstates( any( @b ) != all( @a ) );
[download]

Beauty is in the eye of the beholder, but to my mind's eye that's beautiful. Unfortunately, its simplicity is critically deceptive; don't try this with lists of a thousand elements. Using quantum superpositions on large sets becomes breathtakingly inefficient.

my %tmp;
@tmp{@b} = ();
delete @tmp{@a};
@result = keys %tmp;
[download]

Update: Sheesh, I guess I'm a little slow at writing nodes. I swear those first two replies weren't there before :)

Hi try this with set::Scalar module,

use Set::Scalar;

@a = (1, 2, 3, 4, 5, 6);
@b = ( 3, 4 , 5, 6, 7, 8);

$a = Set::Scalar->new(@a); 
$b = Set::Scalar->new(@b); 
print $b->difference($a);
[download]

Regards,
Gubendran.L