See broquaint's excellent node Of Symbol Tables and Globs.

fixed link

Thank you blazar, johnnywang and broquaint for an excellent education on the Perl symbol space.

Yes... to see if something is a scalar you can do *something{SCALAR}. if it is a scalar then it will exists and it will be defined... (read `perldoc perlmod` if you need more information)

Or you could use the Devel::Symdump package...

I seem to recall that every glob has an SV in the scalar slot as an optimization, but I can't confirm it by reading the source code. (I'm not sure I've even found the right spot in the code.)

Indeed it is so, for when I first tried I noticed that the 'SCALAR' key always seemed to be there, which surprised me and back then I checked into the docs to discover that it was supposed to be so. I think it hasn't changed since...

Is there anyway to find out what the typeglobs really are? (i.e, its scalar value, array value, etc.)

Each slot in the GLOB, if defined, contains a reference to the actual value. The following works for looking up scalars, arrays, and hashes:

for my $g(sort keys %::) { 
  print "$g:\n"; 
  if(defined( *{$g}{SCALAR} ) ) { 
    print "  SCALAR: ", ${ *{$g}{SCALAR} }, "\n"; 
  } 
  if(defined( *{$g}{ARRAY} ) ) { 
    print "  ARRAY: ", join ", ", @{ *{$g}{ARRAY} }, "\n"; 
  } 
  if(defined( *{$g}{HASH}  ) ) { 
    print "  HASH: "; 
    while(my ($k, $v) = each %{ *{$g}{HASH} } ) { 
      print "$k => $v, " 
    } 
  } 
  print "\n" 
}
[download]

I have improved this script a bit, it can recurse into symbol tables now.
I learned something new today. Internals::SvREADONLY can reset the readonly flag :)

my $table=shift||'';
$table.="::";

dumptable($table);

sub dumptable{
my $table=shift;
my $indent=shift||'';
while (my ($key,$value)=each %$table ){
    print qq!$indent"$key":\n!;
    if(defined(*{$value}{SCALAR}) and defined(${ *{$value}{SCALAR}})){
        print "$indent\tSCALAR: ",${*{$value}{SCALAR}}, "\n";
    }
    if(defined( *{$value}{ARRAY} ) ) {
        print "$indent\tARRAY: ", join ", ",@{*{$value}{ARRAY}}, "\n";
    }
    if(defined( *{$value}{HASH}  ) ) {
        if ($key =~ /::$/){
            print "$indent\tSYMTAB:\n";
            dumptable($value,"\t".$indent)
                if (*{$value}{NAME} ne "main::");
        }else{
            print "\tHASH:\n";
            while(my ($k, $v) = each %{ *{$value}{HASH} } ) {
                print "$indent\t\t$k => $v,\n"
            }
        }
    }
    if(defined( *{$value}{CODE}  ) ) {
        print "$indent\tCODE: ",*{$value}{CODE},"\n";
    };
    if(defined( *{$value}{IO}  ) ) {
        print "$indent\tIO: ",*{$value}{IO},"\n";
    };
    print "\n"
}
}
[download]