Pah! Of course you can do it with a proper HTML parser and not have to use regexes:

#!/usr/bin/perl
 
use strict;
use warnings;
 
use HTML::Parser;
my $parser = HTML::Parser->new(
    start_h          => [ \&start, "self,tag,attr" ],
    start_document_h => [ \&init,  "self" ]
);
 
$parser->parse_file('ert.html');
 
foreach my $link ( @{ $parser->{_links} } )
{
    print $link, "\n";
}
 
sub init
{
    my ($self) = @_;
    $self->{_links} = [];
}
 
sub start
{
    my ( $self, $tag, $attribs ) = @_;
 
    if ( $tag eq 'p' && exists $attribs->{class} && $attribs->{class} 
+eq 'g' )
    {
        $self->handler( start => \&get_href, "self,tag,attr" );
    }
}
 
sub get_href
{
    my ( $self, $tag, $attribs ) = @_;
 
    if (   $tag eq 'a'
        && exists $attribs->{href}
        && exists $attribs->{onmousedown} )
    {
        push @{ $self->{_links} }, $attribs->{href};
    }
 
    $self->handler( start => \&start, "self,tag,attr" );
}
[download]

/J\

The problem is that the maximal ("greedy") match consistent with the + in your regexp extends all the way to the last mousedown in the string. Just put a ? after the +, to force a minimal instead of the (default) maximal match.

BTW, I don't see how the use of regexes to weed out unwanted URLs argues in favor of using them to parse HTML. The latter is a much harder problem, due to the presence of nested balanced delimiters. So much harder, in fact, that "true" regular expressions (as opposed to Perl's regexes-on-steroids) cannot solve it.

I think you are far better off with HTML::LinkExtor or HTML::TokeParser to extract the links. Here's how you'd do it with HTML::TokeParser:

my $parser = HTML::TokeParser->new( \$google_results );
my @links_found;
while ( my $token = $parser->get_tag( 'a' ) ) {
  my $url = $token->[ 1 ]{ href };
  next unless $url =~ m{^http://www\.};
  push @links_found, $url;
}
print "$_\n" for @links_found;
__END__
http://www.ets.org/toefl/
http://www.ets.org/testcoll/
http://www.test.com/
[download]

Hi. I added the ? and made the code easier but it's still not giving way.

while($google_results =~ m|<p class=g><a href=(http://.+?)\sonmousedow
+n|gs)
[download]

It works perfectly for me:

while ( $google_results =~
        m|<p class=g><a href=(http://.+?)\sonmousedown|gs) {
  push @links_found, $1;
}
print "$_\n" for @links_found;
__END__
http://www.ets.org/toefl/
http://www.ets.org/testcoll/
http://www.test.com/
[download]

BTW, it's a bit perverse to pick a character like |, which has a special meaning within regexps, as your delimiter for m.

the lowliest monk

have you considered using DBD::Google? (although I'm not sure if it does what you want, I nevered used it, I only know it exists)

(I'm guessing that you are parsing a google page by the name of the var and the output you showed. Or is the purpose to use it on other pages aswell?)