s/(.*)b/$1X/
[download]

Surprised? Really? When the default response to most regular expression questions here seems to be "that is too greedy - insert a ? after the * or +, and then it'll work fine"? We've been burned by too much greediness, so it's really of little surprise that we don't think outside of our boxes ;-)

#!/usr/bin/perl -w

use strict;

my $string = 'aabbcc';

$string = reverse $string;
$string =~ s/b/X/;
$string = reverse $string;

print $string, "\n";

$string = 'aabbcc';

$string =~ s/b([^b]*)$/X$1/;

print $string, "\n";

$string = 'aabbcc';

my $idx;
substr( $string, $idx, 1, 'X') if (-1 != ( $idx = rindex( $string, 'b'
+ ) ));


print $string, "\n";
[download]

$string =~ s/b(?=[^b]*$)/X/;
[download]

$foo = reverse $foo;
$foo =~ s/b/X/;
$foo = reverse $foo;
[download]

s/b[^b]*$/X/;
[download]

$foo = 'aabbcc';

$foo =~ s/(.*)$_/$1X/ for qw(a b c);

print $foo;

STDOUT:
aXbXcX
[download]

use strict;
use warnings;

my $string = "aabbcc";

if($string =~ m{^(aabb)(.*)$})
{
   $string = substr($1,0,length($1)-1) . "X" . $2;
}

print $string;
[download]

print $string = substr($1,0,length($1)-1) . "X" . $2 if $string =~ m{^
+(aabb)(.*)$};
[download]

My advice: use rindex and substr (I'm sure you can figure out yourself how to do this). or a look-ahead (code already posted by Transient, in the update).

Update: I should have taken a better look at Transient's reply... He posted different solutions, including the rindex/substr one...

I don't see what makes the second b in your example the "last" matched character. Matched against what? What is the matching criterion you are using?

Update: BTW, your post suggests that you do not understand the syntax for the s/// operator, which suggests that you don't understand Perl regular expressions at all. I doubt that any answer you get will do you any good until you understand at least the rudiments of regular expressions in Perl. Please read perlretut. You will probably be able to answer your own question then.

Sorry, I do understand regex's but I screwed up my question - I meant to have said I need a way for $foo =~ s/a/X/ to match the LAST letter a, not the first.

And now I see that I can just reverse the string first, then reverse it again after the replace.

I thought maybe there was an option for the s operation that would go in reverse order (like how the g option makes it global in s/a/X/g )

Thanks for your replies.

If you're matching a simple string (e.g. 'b'), as opposed to a general regexp pattern, then I think the rindex solution proposed by Transient and Animator is the way to go. For more complicated matches, you could use a negative look-ahead assertion to single out the last occurrence; e.g. to replace the last occurrence of the pattern /[AB]/ with X, you could use

s/[AB](?!.*[AB])/X/s
[download]

This will replace the last occurrence of A or B with X. The /s modifier is necessary in case the string contains embedded newlines.

the lowliest monk

$str = 'aabbcc';
$str =~ s/a([^a]*)$/X$1/;
print "$str\n";

$str = 'aabbcc';
substr($str, rindex($str, 'a'), 1) = 'X';
print $str;
[download]