There's shouldn't be a loop in the sub month. In fact, something is obviously wrong since $damonth isn't used. Just replace
&month;
with
$month = $mon{$damonth};
or maybe
$month = $mon{0+$damonth};
for it to work.

I'm wondering what you aren't using an array:

my @mon = qw(
   January   Feburary   March
   April     May        June
   July      August     September
   October   November   December
);

...

$month = $mon[$damonth-1];
[download]

And please put <code> tags around your code when you post here. It makes your code easier to read, and you don't have to add a bunch of <br> tags or escape stuff like <.

• Your creation of %mon will work just fine, but it's general practice to use the => in place of some of the commas in order to explictly denote the key => value nature of the relationship. (But as already noted, an array is probably better here anyways.)

  my %mon = ( 1 => 'January', 2 => 'Feburary', 3 => 'March', 4 => 'April
  +', 5 => 'May', 6 => 'June', 7 => 'July', 8 => 'August', 9 => 'Septemb
  +er', 10 => 'October', 11 => 'November', 12 => 'December');
  [download]

• Try to keep output statements separate from the logic. For example, instead of alternating code & print statements, just do a single print at the bottom of the 'for' loop:

  printf 'Certification is %s on %02d % 02d %d<p><HR>',
      $certification, $month, $day, $year;
  [download]

  Kind of trivial here, but what this will do is make the output much easier to understand and modify in the future. (For larger future projects, be sure to investigate things like Template::Toolkit or HTML::Template)
• Be aware of the scope of your variables. In this case, $i, $certification, $number, $month, $day, and $year are all only used inside the for loop. so instead of having the 'my' declaration globally, can just do it in the for loop (this makes it very clear that these variables only exist/have meaning just right here):

  for (my $i=1; $i<=$lines; $i++) {
      my $certification = shift(@data);
      my $number = shift (@data);
      my $month = $mon [$number-1];
      my $day = shift (@data);
      my $year = shift(@data);
      # printf ....
  }
  [download]

• this is a great one for TMTOWTDI .. first off, note that the for ($i=1; $i<=$lines; $i++) construct is very "c-ish" and there are usually 'better' ways to write it in perl.. For example (there's no "right" way here--just a bunch of different ways) the $i is unnecessary in this case:

  while(@data){
    ...
  }
  [download]

  Note that it's still dependent on the file format being sets of 4 lines ..
• One of perl's great strength's is CPAN -- so always remember that if the answer to "is it likely someone else has had to do this?" is "yes" or "most certainly", head to http://search.cpan.org. For example, Date::Calc (there are other Date modules as well) has a Month_to_Text function that does exactly what you need, thus eliminating the need for @mon or %mon or something like that.

  use Date::Calc qw/Month_to_Text/;
  while(@data){
    ...
    my $number = shift (@data);
    my $month = Month_to_Text($number);
    ...
  }
  [download]

C:\tmp>type test.pl
use POSIX;
for my $i (0 .. 11) {
   print strftime( "%B", 0,0,0,1,$i,0),"\n";
}

C:\tmp>test.pl
January
February
March
April
May
June
July
August
September
October
November
December
[download]