use strict;
use warnings;

our ($x, $y) = ('global X', 'global Y');
example();

sub example {
  local $x;
  my $y;
  $x = 'changed local';
  $y = 'changed my';
  example2();
}

sub example2 {
  print "X: $x, Y: $y\n";
}
[download]

Well, as a rule of thumb: use my everywhere, and only if perl complains about, think about using local (e.g. with build in perl variables)

With local, you can also localize parts of datastructures, e.g.

use warnings; use strict;
use vars qw(@array);
@array = 1..20;
print "BEFORE: @array\n";
&TestSub();
print "AFTER: @array\n";
sub TestSub {
  local @array[4..10];
  @array[4..11] = 104..111;
  print "INSIDE: @array\n";
}
[download]

which outputs something like:

BEFORE: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
INSIDE: 1 2 3 4 104 105 106 107 108 109 110 111 13 14 15 16 17 18 19 2
+0
AFTER: 1 2 3 4 5 6 7 8 9 10 11 111 13 14 15 16 17 18 19 20
[download]

beware that 111 is not "localized" and so the change is global.

Best regards,
perl -e "s>>*F>e=>y)\*martinF)stronat)=>print,print v8.8.8.32.11.32"

Hello

my:
your subroutine needs temporary variables. You shouldn't use global variables, because another subroutine might also use the same variables.

local:
All subroutines called from the context of a local variable can access that variable.

$a='one';
$b='two';
sub1();

sub sub1 {
    local $a = 'three';
    my $b = 'four';
    sub2();
}

sub sub2 {
    print "\$a: $a\n";
    print "\$b: $b\n";
}
[download]

Output

$a: three
$b: two
[download]

my variables are statically bound.

sub test_a {
   my $var = "Hello World\n";
}

sub test_b {
   print($var);  # XXX Doesn't print Hello World.
}

test_a();
print($var);  # Doesn't print Hello World.
[download]

local variables are dynamically bound.

sub test_a {
   local $var = "Hello World\n";
}

sub test_b {
   print($var);  # Prints Hello World.
}

test_a();
print($var);  # Doesn't print Hello World.
[download]

However, dynamic binding is rarely used, because its use leads to fragile software. In Perl, local is mostly used to assign a new value to a builtin global, while automatically restoring the global's value when the block is exited.

sub test {
   $_ = $_[0];
   s/([a-z])/uc($1)/eg;
   return $_;
}

foreach (qw(a b c)) {
   print(test($_), "\n");
}

$ perl script.pl
Modification of a read-only value attempted at script.pl line 3.
[download]

It's trying to modify the constant 'a', since $_ is a reference to it. Fix:

sub test {
   local $_ = $_[0];
   s/([a-z])/uc($1)/eg;
   return $_;
}

foreach (qw(a b c)) {
   print(test($_), "\n");
}

$ perl script.pl
A
B
C
[download]

You should really use the wonderful Super Search link you find on the upper-right corner. This topic has an enormous , incredible number of (good) nodes.

Among them:

• Re: What is the difference between 'local' and 'my'?,
• What is the difference between 'local' and 'my'?,
• what is the difference between 'my' and 'local'?