I really like this solution, and decided to play around with it a little. Here it is with a little enhancement...

use warnings;
use strict;

my %arith;
$arith{"+"} = sub { $_[0] + $_[1] };
$arith{"-"} = sub { $_[0] - $_[1] };
$arith{"*"} = sub { $_[0] * $_[1] };
$arith{"/"} = sub { $_[0] / $_[1] }; 

my $problem = "6 + 1";
my $answer;
if ( 
    $problem =~ /^(\d+)\s*(\S)\s*(\d+)$/ 
    and exists $arith{$2} 
) {
    eval {
        $answer = $arith{$2}->( $1, $3 );
    }
} else {
    die "Oops!\nOperation syntax not understood.\n";
}
die "Woops!\n$@" if $@;
print "$answer\n";
[download]

• Modified regexp to require two operands and to make whitespace optional.
• Added basic validity/syntax checking to the results of the pattern match.
• Trapped (and dealt with) possible errors resulting from mathematical operation using the block version of eval. Note, this is the safe version, we're not evaluating quoted text, we're evaluating known code to trap potential errors resulting from mathematical operation errors such as divide by zero.
• Added more robust checking for the existance of a particular mathematical operator in the hashtable.
• Switched to $funcref->(params) notation instead of &$funcref(params).

It's a long way from being a full fledged algeraic expression parser, but it is a little more robust.

Like I did it in Re: Re: How to do that with eval ?:

my %arith = map {
    $_ => eval sprintf 'sub { $_[0] %s $_[1] }', $_
} qw[ + - * / ];
[download]

ihb