Store the name in the $this/$self object, not in the global $_name. $_name was a single variable shared between multiple objects and thus you were always overwriting the value whenever you called myNameIs.

package Interesting;

sub new {
    my ( $class ) = @_;
    return bless {}, $class;
}
 
sub myNameIs{
    my ( $self, $name ) = @_;
    defined $name
        or die "Don't tell me that I don't have a name.";

    # Store the name into the object
    return $self->{name} = $name;
}
 
sub whoAmI{
    my ( $self ) = @_;

    # Retrieve the name from the object.
    return $self->{name};
}
[download]

Separately, I would like to urge you to stop using the syntax $one = new Interesting in favor of $one = Interesting->new. There are some tricky bugs related to the first syntax and you can avoid that entire class of errors by just not using that syntax. If there were a new() function in the same package as the code which had new Interesting, then instead of calling Interesting::new( 'Interesting' ) it would call WhateverPackage::new( 'Interesting' ). In OO code, if you had another class with a method named new(), then you might find that the incorrect new() method was being called.

sub myNameIs {
  ...
  #$_name = $name; don't to this, everyone will have the same name
  $this->{name} = $name;
  ...
}
[download]

I would suggest storing the name in the hash you are using as the object - like with a key such as '_name'. You can then change your methods like:

  sub myNameIs{
    my ($this,$name) = @_;
    die("Don't tell me that I don't have a name.") unless(defined($nam
+e));
    
    $this->{_name} = $name;
  }
  
  sub whoAmI{
    my ($this ) = @_;
    return($this->{_name});
  }
[download]

/J\

The problem is you are using a package-scoped variable ($_name) to store instance data instead of storing it in the object itself. Your methods should be closer to

  sub myNameIs{
    my ($this,$name) = @_;
    die("Don't tell me that I don't have a name.") unless(defined($nam
+e));
    
    $this->{_name} = $name;
  }

  sub whoAmI{
    my $this = shift;
    return($this->{_name});
  }
[download]

FYI in Perl6 (Pugs right now) you can do this as follows:

use v6;
class Interesting {
    has $.name;
    method myNameIs ($name) {
        die "Don't tell me that I don't have a name." 
            unless defined $name;
        $.name = $name;
    }
    method whoAmI () { return $.name; }
}

my $one = Interesting.new;
$one.myNameIs('What');
my $two = Interesting.new;
$two.myNameIs('Who');
my $three = Interesting.new(:name('tukatukatuka SlimShady'));

say "My name is : " ~ $_.whoAmI() for ($one, $two,$three);
[download]

I have written quite a bit of Code where I will use multiple instances of the same Object. The funny thing is that it seems the all of the instances have the same instance data as the last Object that was instatiated.