A hash of hashes will do that nicely,

my %hoh;
my @labels = qw/SAN_Info Criticality_rating Commission_Date/;
while (<>) {
    my ($key, @dat) = split ',';
    $hoh{$key}{$labels[$_] ||= $dat[$_] for 0..$#labels;
}
[download]

Your data contains

Srv_0A,xxxxxxxxx,,xxxxxxxxxxx
Srv_0A,,,
Srv_0A,,,xxxxxxxxxxxxxx
[download]

Should that be

Srv_0A,xxxxxxxxx,,xxxxxxxxxxx
Srv_0A,,,
Srv_0A,,xxxxxxxxxxxxxx,
[download]

If so,

use strict;
use warnings;

my %data;

while (<DATA>) {
   s/^\s+//;
   s/\s+$//;

   my @fields = split(/\s*,\s*/);

   my $server = shift(@fields);
   $data{$server} ||= ['', '', ''];

   # Merge data.
   foreach (0..$#fields) {
      $data{$server}[$_] = $fields[$_]
         if length $fields[$_];
   }
}

print(join(',', $_, @{$data{$_}}), "\n")
   foreach keys(%data);

__DATA__
Srv_0A,Axxxxxxxx,,Bxxxxxxxxxx
Srv_0A,,,
Srv_0G,,,
Srv_0B,Cxxxxxxxxx,,Dxxxxxxxx
Srv_0A,,Exxxxxxxxxxxxx,
Srv_0G,Fxxxxxxxxxx,Gxxxxxxxxxxxxx,
Srv_0B,,Hxxxxxxxxxxxxx,
[download]

If not, how do you merge the two Commission Dates?

The following code assumes that the different data lines are consistent (i.e. for a given ID there is a unique non-empty value for each field):

use strict;
use warnings;

my %data;

while ( <DATA> ) {
  my ( $id, @fields ) = split /\s*,\s*/, $_, -1;
  for my $i ( 0..$#fields ) {
    $data{ $id }[ $i ] = $fields[ $i ] if length $fields[ $i ];
  }
}
__END__
[download]

Update:I've attempted to fix one of the problems pointed out by ikegami below (specifically, added the -1 argument to split). I still focus only on the problem of consolidating from various lines, which I think is what the OP was having problems with, and ingore the issue of output.

Your solution doesn't output anything.

It leaves (any trailing whitespace including the) newlines in the data.

And only creates two fields for Srv_0G, causing the trailing comma to be omitted from the output (which I suppose could be fixed at print-time).