There are (at least) two ways to access sort routines in a different package:

• Prototype the sort subfunction and pass the values as arguments, which can then be accessed by directly indexing @_
• Fully qualifying $a and $b in the sort routine with the package name of the caller (this works because prior to Perl 6 the elements to be compared are passed to the sort routine in the package global variables $a and $b)

use strict;
use warnings;
use my_sort_routines;

package myprogram;

my @data = ( 4, 2, 1, 3 );

my @sorted_proto = sort my_sort_routines::prototyped  @data;
my @sorted_qual  = sort my_sort_routines::qualify_pkg @data;

print @sorted_proto, "\n"; #1234
print @sorted_qual,  "\n"; #1234


package my_sort_routines;

sub prototyped ($$)
{
    # Access the arguments directly by indexing @_

    $_[0] <=> $_[1];
}

sub qualify_pkg
{
    # Qualify $a and $b with the name of the calling package
    # Symbolic refs require "no strict refs" here
    # Symbol::qualify could simplify this, but this illustrates
    # how to do it without an additional module

    my $pkg = caller;
    no strict 'refs';
    ${"${pkg}::a"} <=> ${"${pkg}::b"};
}
[download]

Links:

• sort
• caller
• perlsub (subroutines and prototypes)
• perlmod (packages and modules)
• sort routines crossing package lines (contains benchmark data for prototyping vs non-prototyping)
• Why do we need $a and $b to be special? (discussion of $a and $b)