#!/usr/bin/perl -w

use strict;
use File::Find;

my $dir = '.'; # or wherever

finddepth(\&myrename, $dir);

sub myrename {

    return unless -d; # if you only care about dirs
    return unless / /;
    my $oldname=$_;
    s/ /_/g;
    return if ($oldname eq $_);

        if (rename $oldname,$_) {
              print "renamed  $File::Find::name to $_\n";
        } else {
              warn "Couldn't rename $File::Find::name to $_: $!";
        }
}
[download]

Don't you want to use finddepth() so that by the time you rename the directory File::Find is done with it?

        - tye (but my friends call me "Tye")

Great. It works for me. A minor change I have made. Since $new_name is not declared , it is warning me. Hence I have replaced $new_name to $_ and works. Thanks a lot. One more help. I am new to perl. Can I know what it means of the code?

return unless / /;
[download]

Thanks again. Ashok

It's a regex checking for a space in the name, without which you have no reason to continue the sub.

#!/usr/local/bin/perl -w

use strict;

sub dirs {
        my @retval;
        opendir DIR, ".";
        my @file = readdir DIR;
        closedir DIR;

        for (@file) {
                next if /^\.\.?$/ or -l $_;
                push @retval, $_ if -d $_;
        }

        return @retval;
}


sub rename_dirs {
        my $dir = shift;
        chdir $dir;
        my $newname;

        for (dirs()) {
                rename_dirs($_);
                if (/ /) {
                        ($newname = $_) =~ s/ /-/g;
                        rename $_, $newname;
                }
        }
        chdir "..";
}

rename_dirs($ARGV[0]);
[download]

Update: -l $_ added after receiving a comment by merlyn. thanks!

Broken if you have a symlink. Please don't re-code File::Find unless you know why all the pieces are there. {sigh}

-- Randal L. Schwartz, Perl hacker