$ perl -e 'my $foo = "Hello WorldFoo BarPerl MonksSlash Dot"; my @x = 
+split /(?<=[a-z])(?=[A-Z])/, $foo; print map("[$_]",@x),$/'
[Hello World][Foo Bar][Perl Monks][Slash Dot]
[download]

Using look-behind and look-ahead tags, you end up matching a zero-width point between characters as your split point.

(PS - "bad at regexps"? I find look-behind and look-ahead are relatively rarely used, so it's just a matter of experience - and my experience on this has solely been answering questions here ;->)

Try using the zero-width look-behind and look-ahead matches:

This means that the regex matches at a point where there is a lowercase letter immediately preceding, and an uppercase letter immediately following, but neither of these letters are consumed by the match. More info: perlre

Another way to do it:

my $foo = "Hello WorldFoo BarPerl MonksSlash Dot";
print join (" \n", split (/(?<=[a-z]| )(?=[A-Z])/, $foo));
[download]

my $foo = "Hello WorldFoo BarPerl MonksSlash Dot";
print "$_ \n" for ($foo =~ /([A-Z][a-z]+)/g);

__OUTPUT__
Hello
World
Foo
Bar
Perl
Monks
Slash
Dot
[download]

 my $foo = "Hello WorldFoo BarPerl MonksSlash Dot";
 for ($foo) {
    s/([a-z])([A-Z])/$1|$2/g;
    for (split /\|/ ) {
        print "$_ \n";
    }
}
[download]

I don't care for this approach, because it fails as soon as $foo comes with embedded pipe characters. Then you have to think about escaping existing pipe characters, and so on, until you've reinvented CSV.

-Colin.

WHITEPAGES.COM | INC

Nevertheless, given a set of known data, or a one-time event, this will work just as well. Not that I'm particularly a fan of it either, but it is another way to do it.

Whilst a good point, it would have been helpful to add that a character other than a pipe character could be substituted, thereby avoiding the problem whereby $foo comes with embedded pipe characters. In fact you could use a complex string which you feel is almost guaranteed not to occur!

e.g.

 my $sepstring = '7c6xb1%$#!@#$!@';

 my $foo = "Hello WorldFoo BarPerl MonksSlash Dot";
 for ($foo) {
    s/([a-z])([A-Z])/$1$sepstring$2/g;
    for (split /\Q$sepstring\E/ ) {
        print "$_ \n";
    }
 }
[download]

my $foo = "Hello WorldFoo BarPerl MonksSlash Dot";
for ($foo) {
    for (/[A-Z][a-z]+/g) {
        print "$_ \n";
    }
}
[download]

__OUTPUT__
Hello
World
Foo
Bar
Perl
Monks
Slash
Dot
[download]

although

for ($foo) {
    for (/[A-Z][a-z]+(?:\s[A-Z][a-z]+)+/g) {
        print "$_ \n";
    }
}
[download]

would work.