Re^6: Tk vs browser-based applications

I named the file pizza.pl. Where do I place it so that when I type http://localhost/pizza.pl, the server knows where to locate the file? With apache, I indicate the location of the files via the httpd.conf. Btw, the content of pizza.pl is as follows (from GUI with HTTP::Daemon):

use strict;
use HTTP::Daemon;
use HTTP::Status;
use CGI::Simple;

sub res {
    HTTP::Response->new(
        RC_OK, OK => [ 'Content-Type' => 'text/html' ], shift
    )
}

my %pages = (
    index => sub {
        res qq[
            <html><body>
            <h1>Pizza cost calculator</h1>
            <form method=post action=calc>
            Total cost: <input name=cost><br>
            Number of eaters: <input name=ppl><br>
            <input type=submit value=Submit>
            </form>
            </body></html>
        ];
    },
    calc => sub {
        my ($request) = @_;
        my $cgi = CGI::Simple->new( $request->content );
        res sprintf q[
            <html><body>
            <h1>Result</h1>
            Cost per eater: %.2f<br>
            <a href=index>Again!</a>
            </body></html>
        ], $cgi->param('cost') / $cgi->param('ppl');
    },
);

my $daemon = HTTP::Daemon->new(LocalAddr => '127.0.0.1') or die;

my $ppid = $$;
if (my $pid = fork) {
    while (my $client = $daemon->accept) {
        while (my $request = $client->get_request) {
            my ($page) = $request->url->path =~ m[^/(\w+)$];
            $page ||= 'index';
            if (exists $pages{$page}) {
                $client->send_response( $pages{$page}->($request) );
            } else {
                $client->send_error(RC_NOT_FOUND);
            }
        }
        $client->close;
    }
} elsif (defined $pid) {
    my $url = $daemon->url;
    my @browsers = qw(firefox konqueror mozilla opera start);
    {
        @browsers or die "Couldn't start a browser.";
        my $b = shift @browsers;
        my $r = system("$b $url");
        redo if $r;
    }
} else {
    die "Couldn't fork!";
}
[download]

Comment on Re^6: Tk vs browser-based applications Download Code

Replies are listed 'Best First'.
Re^7: Tk vs browser-based applications by Joost (Canon) on Jul 05, 2005 at 21:56 UTC
This script is the server. As far as I can see, you just run it, then point your browser at http://localhost/. It should do that automatically if you have any of firefox, konquror, mozilla or opera in your $PATH. "What should it profit a man, if he should win a flame war, yet lose his cool?"	[reply]
Re^8: Tk vs browser-based applications by kiat (Vicar) on Jul 06, 2005 at 13:19 UTC
I added Mozilla Firefox (C:\Program Files\Mozilla Firefox\) to the ENV path and then ran the server.pl script but nothing seemed to happen.	[reply]