#!/usr/bin/perl -wl

    use strict;


    my $count = 0;
    my $long;

    open    FILE, "file.txt" or die "Couldn't open file: $!\n";
    binmode FILE;


    while (read FILE, $long, 4) {
        $count += unpack'%32b*', $long;
    }

    print $count;


    __END__
[download]

Or make it more efficient by memoising the calculated values:

    #!/usr/bin/perl -wl

    use strict;


    my $count = 0;
    my %lookup;
    my $byte;

    open FILE, "file.txt" or die "Couldn't open file: $!\n";
    binmode FILE;


    while (read FILE, $byte, 1) {
        next unless ord $byte;

        if ($lookup{$byte}) {
            $count += $lookup{$byte};
        }
        else {
            $count += $lookup{$byte} = unpack'%8b*', $byte;
        }
    }

    print $count;


    __END__
[download]

--
John.

That doesn't work:

>perl -le "print(unpack('%32b*', 0x13))"
7
[download]

There are 3 bits set in 0x13, not 7.

Sorry, my mistake.

>perl -le "print(unpack('%32b*', chr(0x13)))"
3
[download]

See Loops loosing Performance for a recent discussion about this, and this reply in particular. Synopsis: use a 256- or 65536-entry lookup table.

Hugo

open FIN, "dwtest.dat" or die;
my $bytes = do { local $/; <FIN> }; # slurrrrrp
my $bits = unpack "B*", $bytes;
my $count = $bits =~ tr/1/1/;
print "$count\n";
[download]

The slurp gets problematic for very large files, of course, so here is a version that uses a fixed buffer. It runs at essentially the same speed - but uses a constant amount of memory instead.

#!/opt/bin/perl

use strict;
use warnings;
use Time::HiRes qw (gettimeofday tv_interval);

my $file = shift;

my $start_time = [gettimeofday];

open(FH,$file) or die("Can't open file: $!\n");
binmode FH;

my $bytes  = -s $file;
my $cursor = 0;
my $stride = 4000000;
my $counted_bits = 0;

while (1) {
    my $buffer;
    my $result = read(FH, $buffer, $stride);
    if (0 == $result) { 
        last;
    } elsif (not defined $result) {
        warn("Error reading from $file: $!\n");
        last;
    }
    my $bits = unpack "B*", $buffer;
    $counted_bits += $bits =~ tr/1/1/;
}
close (FH);
print "Bits: $counted_bits\n";

my $elapsed = tv_interval($start_time);
my $rate    = $bytes / $elapsed;
print "Bytes per second: $rate\n";
[download]

Besides the performance issue you mentioned, I don't even think that your code works.

You need to fix couple of things:

1. you need & not |
2. you need to do an ord()

Test this:

my $c = chr(0xff);
my $sum = 0;
if ($c) {
    (ord($c) & 0x01) && ($sum++); 
    (ord($c) & 0x02) && ($sum++); 
    (ord($c) & 0x04) && ($sum++); 
    (ord($c) & 0x08) && ($sum++); 
    (ord($c) & 0x10) && ($sum++); 
    (ord($c) & 0x20) && ($sum++); 
    (ord($c) & 0x40) && ($sum++); 
    (ord($c) & 0x80) && ($sum++); 
}
print $sum;
[download]

Your code would look like this (there is no need to count the size of the file, I leave it to you to fix the performance)

use strict;
use warnings;

open(FIN,"perl.exe") or die "cant open file\n"; 
my $sum = 0;
my $c;
while (read(FIN, $c, 1)) {
    if ($c) {
        (ord($c) & 0x01) && ($sum++); 
        (ord($c) & 0x02) && ($sum++); 
        (ord($c) & 0x04) && ($sum++); 
        (ord($c) & 0x08) && ($sum++); 
        (ord($c) & 0x10) && ($sum++); 
        (ord($c) & 0x20) && ($sum++); 
        (ord($c) & 0x40) && ($sum++); 
        (ord($c) & 0x80) && ($sum++); 
    }
} 
print "$sum bits are set\n";
[download]