in reply to urgent perl regexp help needed

With the help of "man perlre" it is easy. Just steal the "match parenthesized group" snippet, and use it as an alternative in the match you want. 
$abc = "abc,xyz,{1,2,3,4},18-90-89,{{1,2},{5,6,7,8}},yts";

$par=qr! \{ (?: [^{}]+ | (??{ $par }) )+ \} !x;

@a= $abc=~ /([^{,]+|$par)/g;

print join("\n",@a);

[download]

Replies are listed 'Best First'.
Re^2: urgent perl regexp help needed
by ikegami (Patriarch) on Jul 20, 2005 at 15:28 UTC

    I'd use * instead of +, since he didn't say empty fields were not allowed. And what if the bracket are is not the first character? Fixed and documented:

    $_ = "abc,xyz,{1,2,3,4},18-90-89,{{1,2},{5,6,7,8}},yts";


# Create a regexp to match nested brackets.

my $par;  # Can't combine this with next line.

$par = qr/ \{             # Opening bracket.
          (?:             # Match zero or more
             [^{}]+       #    non-brackets
             |            #    or
             (??{ $par }) #    bracketed content.
           )*
           \}             # Closing bracket.
       /x;


# Extract fields from the line.

my @elems = / \G                 # Start where last match left off.
              (                  # Capture (return)
                 (?:             #    zero or more
                    [^{,]+       #       non-brackets, non-commas
                    |            #       or
                    $par         #       bracketed content.
                 )*
              )
              (?: , | $)         # Match comma or end of line.
            /xg;


print(join("\n", @elems));

    [download]
[reply]
[d/l]

      thanks a lot!...that was really useful and informative

      Edited by Chady -- added formatting

[reply]
Re^2: urgent perl regexp help needed
by karthikpa (Novice) on Jul 20, 2005 at 15:27 UTC

    Thanks a lot Sec...it worked. Could you please explain to me what exactly you are doing here...I tried reading man pages but there is not much of detail there.

    the help is really appreciated.

    Thanks
    Karthik

    Edited by Chady -- added formatting

[reply]

In Section Seekers of Perl Wisdom