in reply to How to handle a variable number of results from split()?

I'm sure that there's a more compact way to do this, but I think that this does what you are looking for.

I'm also assuming that you meant that each line of your input file had a different number of "dash pairs" such as: 

 --- beginning of data ---
1-2,3-4,2-5
2-1,2-5
3-5,1-9,2-2,4-8
 --- end of data ---

use warnings;
use strict;

while (<>) {
    chomp;
    my @dashpairs = split(/,/);
    foreach my $dashpair (@dashpairs) {
        my ($num1, $num2) = split(/-/,$dashpair);
        print "$num1 - $num2\n";
    }
}

[download]

Replies are listed 'Best First'.
Re^2: How to handle a variable number of results from split()?
by Transient (Hermit) on Jul 20, 2005 at 17:17 UTC
    Aye, there is.. and I'm sure there's a more compact way than this one as well :) 
    #!/usr/bin/perl

use strict;
use warnings;

{
 local ($,,$\) = (" - ","\n");
 while (<DATA>) {
  chomp; print split(/-/) for split(/,/)
 }
}

__DATA__
1-2,3-4,2-5
2-1,2-5
3-5,1-9,2-2,4-8

    [download]
[reply]
[d/l]
      Well, if that's exactly how you want the output: 
      {
  local $/;
  local $_ = <DATA>;
  s/,/\n/g;
  s/-/ - /g;
  print
}

      [download]
      Or 
      open P, ' | perl -laF, -ne "s/-/ - /, print for @F" ';
print P <DATA>;
close P;

      [download]
      (Some things are done more succinctly on the command line.)
[reply]
[d/l]
[select]
Re^2: How to handle a variable number of results from split()?
by Anonymous Monk on Jul 21, 2005 at 08:20 UTC
    thanks for ur help, this certainly does help
[reply]

In Section Seekers of Perl Wisdom