use strict;
use warnings;

my %HoHoA = (
              'set1' => {
                         'key1_set1' => [ 'some arrays' ],
                         'key2_set1' => [ 'some arrays' ],
                       },

              'set2' => {
                         'key1_set2' => [ 'some arrays' ],
                         'key2_set2' => [ 'some arrays' ],
                       },

              'set3' => {
                         'key1_set3' => [ 'some arrays' ],
                         'key2_set3' => [ 'some arrays' ],
                       },

              'set4' => {
                         'key1_set4' => [ 'some arrays' ],
                         'key2_set4' => [ 'some arrays' ],
                         'key3_set4' => [ 'some arrays' ],
                       },

);

# sikl stands for "sorted inner key lists"
# @sikl is a SAoSA: a sorted array of sorted arrays
my @sikl =
  map sort_inner( [ keys %{ $HoHoA{ $_->[ 0 ] } } ] ),
  sort { $a->[ 1 ] <=> $b->[ 1 ] }
  map [ $_, substr( $_, 3 ) ],
  keys %HoHoA;

for my $i ( 0..$#sikl-1 ) {
  my $si = $sikl[ $i ];
  for my $j ( $i+1..$#sikl ) {
    my $sj = $sikl[ $j ];

    for my $ki ( @$si ) {
      for my $kj ( @$sj ) {
        print "$ki - $kj\n";
      }
    }

  }
}

sub sort_inner {
  return [
          map $_->[ 0 ],
          sort { $a->[ 1 ] <=> $b->[ 1 ] || $a->[ 2 ] <=> $b->[ 2 ] }
          map [ $_, /\d+/g ],
          @{ $_[ 0 ] }
         ]
}
__END__
[download]

key1_set1 - key1_set2
key1_set1 - key2_set2
key2_set1 - key1_set2
key2_set1 - key2_set2
key1_set1 - key1_set3
key1_set1 - key2_set3
key2_set1 - key1_set3
key2_set1 - key2_set3
key1_set1 - key1_set4
key1_set1 - key2_set4
key1_set1 - key3_set4
key2_set1 - key1_set4
key2_set1 - key2_set4
key2_set1 - key3_set4
key1_set2 - key1_set3
key1_set2 - key2_set3
key2_set2 - key1_set3
key2_set2 - key2_set3
key1_set2 - key1_set4
key1_set2 - key2_set4
key1_set2 - key3_set4
key2_set2 - key1_set4
key2_set2 - key2_set4
key2_set2 - key3_set4
key1_set3 - key1_set4
key1_set3 - key2_set4
key1_set3 - key3_set4
key2_set3 - key1_set4
key2_set3 - key2_set4
key2_set3 - key3_set4
[download]