I think line 22 just refers to the start of the if chain. This is start of your problem:

elsif ($dungeon[$start] eq '#' && $dungeon[$start] + 1 eq '#'
[download]

You probably want to do the "+1" inside the brackets.

To the second part of your question, you'll probably have an easier time with your project if you try some of these tips:

• Parameterize your sizes and use them in your code; it will help you catch logical errors and makes it easier to test how it works on a small size array
• Parameterize your map symbols; easier to change later and easier to understand in the logic of your code
• Write in logical paragraph and consider commenting them for clarity of intent
• Replace some of your loop flags and "init then increment" loops with logic that more closely resembles what you're trying to do

I've revised parts of your example to show what I mean. (Not the most Perlish way to do it, but a step closer that should be clear to see the difference.) I've left out most of your room logic as it wasn't clear what you intended.

#!/usr/bin/perl
use strict;
use warnings;

my ($dungeon_width, $dungeon_height) = (20, 20);
my $WALL = '#';
my $ROOM = '.';

my @dungeon = ($WALL) x ( $dungeon_width * $dungeon_height );         
+   

sub generatemap {

    # clear a starting location
    my $cur_location = int rand( @dungeon ); # 0 to $#dungeon
    $dungeon[ $cur_location ] = $ROOM;

    # clear squares for (about) half the dungeon
    my $room_count = 1; 
    while ($room_count < @dungeon / 2) {

        # pick a square adjacent to the current one
        my $choice = (-1, +1, -$dungeon_width, +$dungeon_width)[int ra
+nd 4];
        my $new_location = $cur_location + $choice;

        # pick again if it would take us out of bounds
        if  ($new_location < 0 || $new_location > $#dungeon) {
            redo;
        }

        # clear it if it's not already a room
        $cur_location = $new_location;
        if ( $dungeon[ $cur_location ] ne $ROOM ) {
            $dungeon[ $cur_location ] = $ROOM;
            $room_count++;
        }
    }
}

sub printmap {
    for my $row (0 .. $dungeon_height - 1) {
        my $first_col = $row * $dungeon_width;
        my $last_col  = $first_col + $dungeon_width - 1; 
        print @dungeon[ $first_col .. $last_col ], "\n";
    }
}

generatemap;
printmap;
[download]

-xdg

Code written by xdg and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.

elsif ($dungeon[$start] eq '#' && $dungeon[$start] + 1 eq '#'
[download]

elsif ($dungeon[$start] eq '#' && $dungeon[$start+1]  eq '#'
[download]

Let me add Games::Dice::Probability as another handy bit of code... written by a friend of mine.

--
$you = new YOU;
honk() if $you->love(perl)

I'd recommend storing it internally as something else, and only converting it to a # in printmap. The fewer \# you have, the better.

Some of this you're going to have to debug yourself -- PM is not a line-by-line debugging service. You're already using "strict" and "warnings", which is good-- both are very good programming practices and will help you greatly. You might also want to try "use diagnostics" or look up the meaning of the warning you're getting in perldiag.

-xdg

Code written by xdg and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.

You may like this recursive solution:

use warnings;
use strict;

my $rows = 21; # Must be odd and > 3
my $cols = 41; # Must be odd and > 3
my $cells = $rows * $cols;

my @dungeon = ('X') x $cells;

sub dAt
{
my ($x, $y) = @_;
return \$dungeon [$x + $y * $cols];
}


sub generatemap
{
my ($x, $y) = @_;
my $dirCount = 0;
my $dir = int rand (4);

while ($dirCount++ < 4)
  {
  $dir = 0 if $dir > 3;
  my ($xInc, $yInc) = @{([0, 2], [2, 0], [0, -2], [-2, 0])[$dir]};
  my ($xNew, $yNew) = ($x + $xInc, $y + $yInc);
  next if $xNew < 0 || $xNew >= $cols || $yNew < 0 || $yNew >= $rows;
  next if ${dAt ($xNew, $yNew)} eq '.';

  ${dAt ($x + $xInc / 2, $y + $yInc / 2)} = '.';
  ${dAt ($xNew, $yNew)} = '.';
  generatemap ($xNew, $yNew);
  }
  continue {$dir = 0 if ++$dir > 3;}
}

sub printmap
{
my $first = 0;
while ($first < $cells)
  {
  print join "", @dungeon [$first..($first + $cols - 1)];
  print "\n";
  $first += $cols;
  }
}

${dAt (1, 1)} = '.';
generatemap (1, 1); #Start in top left corner - gota go there anyway
printmap;
[download]