The simple, but presumably wrong, answer is that the file contents can just be slurped into a string and the string passed to the subroutine. Why is that the wrong answer?

open infile, "< datafile";
my $str = join "", <infile>;
close infile;
gnuplot (..., $str);
[download]

I think that OP want's the contents of the file eval'd .. so, to OP, i would say start with something live the above and simply perldoc -f eval it. Be aware, however, that this can be very dangerous--for example if someone puts malevalent perl code in the file it _will_ get executed.

open FILEHANDLE, '<', '/tmp/MY_DATA' or die $!;
my $str = do { local $/; <FILEHANDLE> };
close FILEHANDLE;
gnuplot({ "title" => "My Trend",
          "output type" => "png",
          "output file" => "$TMPDIR/trend-$$.png"},
           eval($str),
       );
[download]

(Note: For slurp explaination, see Perl Idioms Explained - my $string = do { local $/; <FILEHANDLE> };)

You teach one 'do' idiom, but then you skip the other power of 'do' and go the long way around.

die if not -f '/tmp/MY_DATA';
gnuplot({ "title" => "My Trend",
          "output type" => "png",
          "output file" => "$TMPDIR/trend-$$.png"},
          do '/tmp/MY_DATA'
       );
[download]

(Not that this is an endorsement of either approach.)

--
[ e d @ h a l l e y . c c ]

Sounds like what you're trying to do is use one script to generate your data and another to plot it, and you want to be able to save your data to a file in-between. Is that it? If you're manually generating a "Perl-format" data structure and dumping that to a file, you're probably better off using various CPAN modules that help you serialize a Perl data structure and save it to a file. For example, Data::Dumper (and variants like Data::Dump) or YAML. Let's consider an example with YAML;

use YAML qw( DumpFile );

my @data = (
    [
        {
            "title" => "line 1", 
            "style" => "lines" , 
            "type" => "matrix"
        }, 
        [ 1, 6318 ], 
        [ 2, 7903 ], 
        [ 3, 25617 ], 
    ],
    [
        { 
            "title" => "line 2", 
            "style" => "lines" , 
            "type" => "matrix"
        }, 
        [ 1, 6215 ], 
        [ 2, 7831 ], 
        [ 3, 25782 ],
    ],
);

DumpFile( "output.txt", @data )
[download]

This produces an output file that looks like this:

--- #YAML:1.0
- style: lines
  title: line 1
  type: matrix
-
  - 1
  - 6318
-
  - 2
  - 7903
-
  - 3
  - 25617
--- #YAML:1.0
- style: lines
  title: line 2
  type: matrix
-
  - 1
  - 6215
-
  - 2
  - 7831
-
  - 3
  - 25782
[download]

Loading it back in from inside your other file is just the reverse, and then you can use it however you want:

use YAML qw( LoadFile );

my @data = LoadFile( "output.txt" );

gnuplot({ "title" => "My Trend",
          "output type" => "png",
          "output file" => "$TMPDIR/trend-$$.png"},
           @data
       );
[download]

One advantage of YAML is that it's not Perl code, so you don't run the same "danger" in loading Perl code from a file and running "eval" or just running "do" on the file. (If it's just you using it, it's not much of a risk, but it's a bad habit to get into.)