my %hosts;

while (<IN_FILE>) {
   chomp;
   my ($ip, @aliases) = split(/\s+/, $_);

   foreach my $alias (@aliases) {
      $hosts{$ip}{$alias} = 1;
   }
}

foreach my $ip (sort keys %hosts) {
   my @aliases = sort keys %{$hosts{$ip}};
   print OUT_FILE ("$ip ", join(' ', @aliases), "\n");
}
[download]

while(<FH>){
 chomp;
 my @fields = split;
 my $ip = shift @fields;
 foreach ( @fields ){
  $masterhash{$ip}{$_} = 1;
 }
}
[download]

for my $ip ( keys %masterhash ){
 print "$ip ", join (" ",keys %{$masterhash{$ip}}),"\n";
}
[download]

Looks like you need a hash of hashes instead. Something like this (untested):

my %master;
while (<>)
{
  my @line = split ' ';
  foreach my $alias ( @line[1..$#line] )
  {
    $master{$line[0]}{$alias}++;
  }
}
foreach my $ip ( sort keys %master )
{
  print "$ip ", 
        +join( ' ', sort keys %{$master{$ip}}), 
        "\n";
}
[download]

Here is what it looks like as a hash of arrays. It's not as scalable as a hash of hashes, since it needs to grep through the array of aliases each time, but on small files you shouldn't notice.

use strict;

# Hash of arrays
# USAGE: $masterhash{$ipaddress} = @aliases
my %masterhash;

my $input_file  = "test.in";
my $output_file = "test.out";

open INPUT_FILE, "<$input_file" or die "Could not open $input_file\n";

# Loop through each line in the input file
while(my $line = <INPUT_FILE>)
{
  # Split line on spaces
  my @line_parts = split(/\s/, $line);
  
  # Grab the IP address
  my $ipaddress = shift @line_parts;
  
  # Loop through the aliases
  foreach my $alias (@line_parts)
  {
    # Search through the array for that IP address to determine
    # whether or not the current alias is already there
    # 
    # The value in $masterhash{$ipaddress} is an array reference, so
    # we have to wrap it with a @{} to use it as an array 
    unless(grep {$_ eq $alias} @{$masterhash{$ipaddress}})
    {
      # If we get here, its a new alias for this IP address so add it
      push @{$masterhash{$ipaddress}}, $alias;
    }
  }
}

# Printing output...
open OUTPUT_FILE, ">$output_file" or die "Could not open $output_file\
+n";

# Print one line per IP address
foreach my $ip (sort keys %masterhash)
{
  # Print the IP, followed by all of its aliases joined by spaces.
  print OUTPUT_FILE ("$ip ", join(" ", sort @{$masterhash{$ip}}), "\n"
+);
}
[download]


test.in

IPADDRESS alias1 alias2 alias5
IPADDRESS2 alias3 alias4
IPADDRESS2 alias3 alias5
IPADDRESS2 alias3 alias5
[download]


test.out

IPADDRESS alias1 alias2 alias5
IPADDRESS2 alias3 alias4 alias5
[download]

Hope this helps!

(Was your reply misplaced?)

Your comment is wrong, but your code works:

# USAGE: $masterhash{$ipaddress} = @aliases
[download]

That's the same as:

$masterhash{$ipaddress} = scalar @aliases
[download]

What you want in this case is:

$masterhash{$ipaddress} = \@aliases
[download]

The only justification for array of hashes I can come up with is if the number of entries is very large, and you manage duplicate hosts. (For example, the file is already sorted by host, and you keep track of the last host. If the current host is the same, the new data is added to the last host entry. Otherwise, a new host entry is created first.) But searching the host array to find the correct entry on a large array is problematic.

-QM
--
Quantum Mechanics: The dreams stuff is made of

$ip0 = $masterarray[0][0];
push(@{$masterarray[0]}, 'alias8');
[download]

use strict;

# start by extracting all unique information from file
my %addresses = ();
while (<>)
{
    my ( $addr, @aliases ) = split( /\s+/, $_ );
    foreach my $alias ( @aliases )
    {
        $addresses{$addr}->{$alias} = 1;
    }
}

# write out unique information in requested format
my @masterarray = ();
foreach my $addr ( keys %addresses )
{
    my @aliases = ();
    foreach my $alias ( keys %{$addresses{$addr}} )
    {
        push( @aliases, $alias );
    }
    push( @masterarray, [ $addr, @aliases ] );
}

# print out array
foreach my $masterline ( @masterarray )
{
    print( join( ' ', @{$masterline} ) );
    print( "\n" );
}
[download]

When supplied with a data file matching your input it outputs the following:

C:\temp>perl -w test.pl testdata.txt
IPADDRESS alias1 alias2 alias5
IPADDRESS2 alias3 alias4 alias5
[download]