Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:

Hi Monks, I need to subsitute tailing commas at the end of a line with white space e.g. 
234,456,

[download]
would become 
234,456

[download]
I have the following code 
open (FH, "...");

while (<FH>) {

s/\,$//;

print FH $_;
}

[download]
This does the subsitution but the file contains both lines? Thanks

Replies are listed 'Best First'.
Re: read and write to same file
by reneeb (Chaplain) on Aug 19, 2005 at 10:48 UTC 
    #! /usr/bin/perl

use strict;
use warnings;
use Tie::File;

my $file = '/path/to/file.ext';

tie my @array,'Tie::File',$file or die $!;
$_ =~ s/,$/ / for(@array);
untie @array;

    [download]
    see Tie::File
[reply]
[d/l]

      For this, a one-liner works, too:

      $ perl -p -i -e 's/,$/ /' somefile.txt

      [download]

      -xdg

      Code written by xdg and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.

[reply]
[d/l]
      thanks for that, another new module to add to the list
[reply]
Re: read and write to same file
by Anonymous Monk on Aug 19, 2005 at 11:41 UTC
    In general, to read/write to a file, you need to open the file read/write, and if you want to write back a line you just read, you need to seek back to the beginning for the line before writing. But it gets complicated if the line you are writing back have a different length. On Unix and Windows, files are just streams of bytes, neither the OS, nor the filesystem have any concept of a "lines" - lines are there for us humans.

    The easy solution in your case would be to make use of either a temporary file, or to slurp in the entire file into memory. With many systems now having at least 256 Mb of memory, slurping in entire files isn't too bad (although I wouldn't do it with a 5 Gb file). Some untested code: 

    use Fcntl 'SEEK_SET';
open my $fh, "+<", $file or die;
local $/;
local $_ = <$fh>;
s/,(?=\n|$)//g;
seek $fh, 0, SEEK_SET or die;
print $fh $_ or die;
truncate $fh, tell $fh or die;
close $fh or die;

    [download]
    Do not forget the truncate, this is needed if you have actually deleted any commas - the text to write back will be shorter, and you don't want the trailing old part of the file.

    And for a one-liner: 

    perl -pi -le 'BEGIN{$/=",\n"}' file

    [download]
[reply]
[d/l]
[select]
Re: read and write to same file
by aukjan (Friar) on Aug 19, 2005 at 10:59 UTC

    If you know that each line has a ',' you can also use chop instead of the RE

    Go Fish!

[reply]
      Unless I'm missing something, chop will take of the end of line character first, based on $/. So you'd have to chomp (to safely remove the possibly non-existent end of line character) then chop. Then put the end of line character back on, assuming there was one to begin with. Or chop once, check to see if it was an eol character, and chop again for the comma and tack the eol character back on.

      So. Am I missing something obvious here?

[reply]

        this posting was absolutely well-formed and correct, but nobody posted a question matching to my answer, so I removed it... it was too early in the morning...

        Please, dear NodeReaper, would you mind removing my posting

        Best regards,
        perl -e "s>>*F>e=>y)\*martinF)stronat)=>print,print v8.8.8.32.11.32"

[reply]

Back to Seekers of Perl Wisdom