I recommend taking a look at DateTime. A local tutorial may be found here: Getting started with DateTime, and there is also a DateTime FAQ.

HTH,

I think planetscape's answer is sufficient for most purposes. The really reliable answer is to always keep time in UTC. With no time zones and daylight politicking, timekeeping is remarkably simple.

DateTime can do many things beside simple duration formatting. It can manipulate dates and time and convert them between timezones to most points in history. You can even convert your dates to the Julian calendar or even Tolkien's shire calendar. But if you don't need all that don't bother with DateTime (but think about it carefully, will you be writing some other code in the future to work with these dates? If so, then use DateTime)

The Butter Knife
The following is the non-DateTime way to do it. The math is fairly simple and I've put it into constants so you can follow it easily.

Start with finding out how many of the largest period (weeks) are in the duration, then subtract that from the duration and move to the next level of precision. In the end you'll be left with seconds.

sub doSomethingHere {
    my $duration = shift;

    my $MINUTE = 60;
    my $HOUR   = 60 * $MINUTE;
    my $DAY    = 24 * $HOUR;
    my $WEEK   = 7  * $DAY;

    my $weeks = int($duration / $WEEK);
    $duration -= $weeks * $WEEK;

    my $days = int($duration / $DAY);
    $duration -= $days * $DAY;

    my $hours = int($duration / $HOUR);
    $duration -= $hours * $HOUR;

    my $minutes = int($duration / $MINUTE);

    my $seconds = $duration - $minutes * $MINUTE;

    return ($weeks, $days, $hours, $minutes, $seconds);
}
[download]

use Date::Calc qw /Localtime Delta_YMDHMS/;
my @then = (Localtime(1112241312))[0..5];
my @now = (Localtime(time))[0..5];
print join ":", Delta_YMDHMS( @now, @then );   # S,M,H,D,M,Y
[download]

use Date::Calc qw/Delta_Days/;
print Delta_Days( @now[0..2], @then[0..2] ) / 7;
[download]

Let's use the Date::Manip module.

use Date::Manip; 
($weeks,$days,$hours,$minutes,$seconds) = 
    Delta_Format($timespan . "s", 0, qw"%wh %dv %hv %mv %sd");
[download]

Or, using technology from the future (compared to your question)

use Date::Manip 6.13; 
my $deltao = Date::Manip::Delta->new($timespan . "s");
($weeks,$days,$hours,$minutes,$seconds) = 
    $deltao->printf(qw"%www %ddd %hhh %mmm %sss");
[download]