Perl subs nearly all handle any number of arguments, passed in as aliases in @_. Perl has printf which works just like the C function.

sub printf_like {
    my ($fmt, $flag) = (shift(), 1);
    printf $fmt, $_ or $flag = 0 for @_;
    return $flag;
}
[download]

In Perl, the arguments to subs/functions are sent as lists. So you can put your first element as the format and the subsequent elements are the args you want to send. Here is a dummy function that does something like that

#!/usr/bin/perl -w

use strict;

my @ret = pow("3 2 3 2",(2,3,5,7));
print +($_,$/) for @ret;

sub pow {
    my ($fmt, @values) = @_;
    my @fmts = split /\s+/, $fmt;

    return map {$_**shift(@fmts) } @values;
}
__END__
8
9
125
49
[download]

The first param's first element tells you by what power the first arg should be raised.

Hi,

Could be something like this...

sub recordStatus {
    if($m_bUseLog and $iLogLevel <= $m_iLogLevel) {
        my $format = shift;
        my $string = sprintf $format, @_;
        return length $string if(print $m_sSourceFile $string);
        return -1;
    }
}
[download]

This would be something like you have, having $m_bUseLog, $iLogLevel, $m_iLogLevel, $m_sSourceFile, as global variables. Where $m_sSourceFile is the FILEHANDLE...

In the C++ as in the Perl, you should add some errors check, from input and also define a common error return (if return -> croack)...

Regards,

Close, I think. However, given that we're coming from C++ to Perl, chances are that "m_" means "member variable". In other words, we're in an object method here.

sub recordStatus {
    my $self = shift;
    if($self->{UseLog} and $iLogLevel <= $self->{LogLevel}) {
        my $format = shift;
        my $fh = $self->{SourceFile};
        my $string = sprintf $format, @_;
        return length $string if(print $fh $string);
        return -1;
    }
}
[download]

Although, to be honest, the return code from the function probably doesn't matter. I've left it in as a strict interpretation of the OP would mandate it, but likely we could bypass the intermediate sprintf and just printf directly to the output, returning the boolean value that printf returns. It would change the signature by a small bit, but it would probably be a good bit. ;-) Strict porting isn't that great of an idea in the long term anyway.

Hi,

Oh, yeah, I forgot the ++ from the C ;-)

Regards,

|fire| at irc.freenode.net