You can turn off backup feature but it is dangerous or rather not a good idea.

code below is untested

{
  local $^I = ".bak";
  local *ARGV;
  @ARGV = "mydata.txt";
  while (<>) {
    s/idTag/newTag/g;
    print;
  }
}
[download]

sounds interesting thank you.

Look at the Tie::File module. It allows you to edit a file in-place as if it were an array.

This example replaces any line containing $idtag with a line containing $replacement.

use Tie::File;

my $file = 'filename';
my @tied_file;

my $idtag = 'idTag';
my $replacement = 'replacement line';

# Create the array @tied_file from $file
tie(@tied_file, 'Tie::File', $file);

# Preserve the index so we can work directly on lines of @tied_file
foreach my $i (0 .. $#tied_file) {

    if ($tied_file[$i] =~ /$idtag/) {

        # Do something to this line of @tied_file
        $tied_file[$i] = $replacement;

    }

}

untie(@tied_file);
[download]

Thank you, this is just the bit I needed. I suggest you put this in the snippets barn,as it might prove to be useful to a lot of people.
keyword-> read write file
Thanks again!

-Chuck

# untested substitution
perl -pi -e 's/^.+idTag.+$/new data here/' file.txt
[download]

first option