This is part a usenet article I posted a while back in response to someone who was doing something similar. I hope it is helpful and interesting.

---

But finally, you might find a different approach amusing. You need the following utility module. Put the this code into the file Devel/Dumpcode.pm:

        package Devel::Dumpcode;

        sub DB::DB { }    # Do nothing special
        
        sub main::source_of_function {
          my $package = caller;
          $function = $package . '::' . shift();
          my ($file, $start, $end) =
            $DB::sub{$function} =~ /(.*):(\d+)-(\d+)/;
          @{"::_<$file"}[$start..$end];
        }

        1;
[download]

Then put the following into tryme.pl:

        #!/usr/bin/perl

        for (;;) {
          print "Gen = ", Gen_val(), "\n";
          my @code = source_of_function('Gen_val');
          for (@code) {
            last if s{(\d+)(?=;\s+\# EDIT ME)}
                     {(($1 * 1103515245 + 12345) / 65536) % 32768}e;
          }
          eval join '', @code;
        }

        sub Gen_val {
          1;     # EDIT ME
        }
[download]

Now use:

        perl -d:Dumpcode tryme.pl
[download]

Now it doesn't have to open the source code file. I hope you're entertained!

The nice thing about this is that although it is a genuinely useful and effective technique, it's also extremely bizarre.