in reply to Is it possible to use key/values of a Hash/Hash ref while it's being initialized?

The value of key1 has to be laying around somewhere?!?

No, but you can bookmark it if you want: 

my %hash = map {
                  my $foo;
                  $_ => {
                          key1 => $foo = 'longstring'.$_.'more',
                          key2 => alter( $foo ),
                        }
               } @list;

[download]

That would work, though I am not sure I would recommend it. A two-stage approach would/might be cleaner, I think: 

my %hash = map {
                  my $foo = { key1 => 'longstring'.$_.'more' };
                  $foo->{"key2"} = alter( $foo->{"key1"} );
                  $_ => $foo;  
               } @list;

[download]

Actually, now that I've written both, I can't decide which is cleaner.

Replies are listed 'Best First'.
Re^2: Is it possible to use key/values of a Hash/Hash ref while it's being initialized?
by ikegami (Patriarch) on Sep 15, 2005 at 02:35 UTC

    or

    my %hash = map { my $foo = 'longstring'.$_.'more';
                 $_ => { key1 => $foo,
                         key2 => alter($foo) }     }
           @list;

    [download]

    or (the wacky)

    my %hash = map { $_->[0] => { key1 => $_->[1],
                              key2 => alter($_->[1]) } }
           map { [ $_ => 'longstring'.$_.'more' ] }
           @list;

    [download]

    or (the efficient)

    my %hash;
foreach (@list) {
   my $foo = 'longstring'.$_.'more';
   $hash{$_} = {
      key1 => $foo,
      key2 => alter($foo),
   };
}

    [download]

    or (using auto-vivification)

    my %hash;
foreach (@list) {
   my $foo = 'longstring'.$_.'more';
   $hash{$_}{key1} = $foo;
   $hash{$_}{key2} = alter($foo);
}

    [download]

    or

    my %hash;
foreach my $key (@list) {
   foreach ('longstring'.$key.'more') {
      $hash{$key} = {
         key1 => $_,
         key2 => alter($_),
      };
   }
}

    [download]

    or

    my %hash;
foreach my $key (@list) {
   foreach ('longstring'.$key.'more') {
      $hash{$key}{key1} = $_;
      $hash{$key}{key2} = alter($_);
   }
}

    [download]

    or (in two steps)

    my %hash = map { $_ => { key1 => 'longstring'.$_.'more' } }
           @list;

$hash{$_}{key2} = alter($hash{$_}{key1})
   foreach keys %hash;

    [download]

    Updated: Added more alternatives.

    Updated: Fixed bug. Changed $_ to $key in the concatenation in later snippets.

    Updated: Added more alternatives.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom