Petras has asked for the wisdom of the Perl Monks concerning the following question:

Hi, Everybody!

I've finally finished the Llama and have started on the Emu. I'm trying to make a simple Perl/Tk program that displays a grid of Checkbuttons. I want to call a subroutine when the buttons are checked/unchecked (same sub eitherway). Here's the code that works (works but without calling the sub):

#!perl 
use warnings;
use strict;
use Tk;

my $mw = MainWindow->new;
$mw->title("Checkbutton Grid");

my $x_size = 5;
my $y_size = 5;
my %b_name;

for (my $x=0; $x<$x_size; ++$x) {
  for (my $y=0; $y<$y_size; ++$y) {
    $mw -> Checkbutton (
           -activebackground => "white",
           ) -> grid (
                -row => $x, 
                -column => $y
                );
  }
}
MainLoop;

[download]

But this doesn't do what I expect it to:
    $mw -> Checkbutton (
           -activebackground => "white",
           -command => &react ("\"$x\_$y\"");
           -command => print "hi"  # <= this is a change
           ) -> grid (
                -row => $x, 
                -column => $y
                );
....
sub react {
  print "$_[0]\n";
}

[download]

From the text it seems that when I check/uncheck a Checkbutton that the shell window should print the grid coordinates. Instead, when the script is run the 25 sets of coordinates go straight to the window and nothing happens when the Checkbuttons are checked/unchecked. What am I missing?

For a free bonus, if more-experienced-posters-than-I want to clue me in on the appropriate use of READMORE I'd be willing to learn! cog already instructed me on signatures ;)


UPDATE:pg has the code for what I was looking to do. The other blessed and beautiful monks who replied were all right, their answers match what the Emu says. I was wanting to be able to call a sub through -command and discovered how last night reading the source code for some of the examples in widget.exe. This (thanks, pg and widget.exe authors) is what does what I wanted to do:
-command => [\&display, $x, $y]

[download]

So, thanks everyone, for your part in my learning experience.

Cheers!
-P
Don't worry about people stealing your ideas. If your ideas are any good, you'll have to ram them down people's throats.
-Howard Aiken

Replies are listed 'Best First'.
Re: Perl/Tk : Trouble with commands and Checkbuttons
by pg (Canon) on Sep 16, 2005 at 06:03 UTC 
    use warnings;
use strict;
use Tk;

my $mw = MainWindow->new;
$mw->title("Checkbutton Grid");

my $x_size = 5;
my $y_size = 5;
my %b_name;

for (my $x=0; $x<$x_size; ++$x) {
  for (my $y=0; $y<$y_size; ++$y) {
    $mw -> Checkbutton (
           -activebackground => "white",
           -command => [\&display, $x, $y]
                       ) -> grid (
               -row => $x,
               -column => $y
                );
  }
}
MainLoop;

sub display {
    my ($x, $y) = @_;
    print "($x, $y)\n";
}

    [download]
[reply]
[d/l]
Re: Perl/Tk : Trouble with commands and Checkbuttons
by spiritway (Vicar) on Sep 16, 2005 at 05:34 UTC

    Your code as posted doesn't compile. You've got a couple of typos in it...

    Try this:

    #! /usr/bin/perl 
use warnings;
use strict;
use Tk;

my $mw = MainWindow->new;
$mw->title("Checkbutton Grid");

my $x_size = 5;
my $y_size = 5;
my %b_name;

for (my $x=0; $x<$x_size; ++$x) {
  for (my $y=0; $y<$y_size; ++$y) {
    $mw -> Checkbutton (
           -activebackground => "white",
           -command => sub { print "$x,$y\n";
                       print "hi"; }
                       ) -> grid (
               -row => $x,
               -column => $y
                );
  }
}

MainLoop;

    [download]

    Note that when you want to call a subroutine in a -command line, you need to use the sub { ... } language. Note also that the values for $x and $y will be $x_size and $y_size respectively, because by the time you click on a check button, they've been incremented to those values - where they remain.

    What you need to do is to associate a value (x, y) with each of the check buttons, and then use the value in your print statement.

[reply]
[d/l]

      This will not work, and will print 5,5 regardless which checkbutton you click. The issue is that you used the latest value of $x and $y, not the value at the time when the checkbutton is defined.

[reply]

        So a minor change to allow the closure to close on the current value would be to create new variables: 

        #! /usr/bin/perl 
use warnings;
use strict;
use Tk;

my $mw = MainWindow->new;
$mw->title("Checkbutton Grid");

my $x_size = 5;
my $y_size = 5;
my %b_name;

for (my $x=0; $x<$x_size; ++$x) {
    for (my $y=0; $y<$y_size; ++$y) {
        my $x_cord = $x;
        my $y_cord = $y;
        $mw -> Checkbutton (
                            -activebackground => "white",
                            -command => sub { print "$x_cord,$y_cord\n
+";
                                print "hi"; }
                           ) -> 
            grid (
                  -row => $x,
                  -column => $y
                 );
    }
}

MainLoop;

        [download]
        I'm not saying this is more efficient or better than your other example below (probably is neither), just that it's closer to the OP tried to do while still working.

[reply]
[d/l]
Re: Perl/Tk : Trouble with commands and Checkbuttons
by Sandy (Curate) on Sep 16, 2005 at 15:28 UTC
    Just as a side note:

    The -command requires a reference to a subroutine, not code.

    So... your code snippet 

    $mw -> Checkbutton (
           -activebackground => "white",
           -command => &react ("\"$x\_$y\"");
           -command => print "hi"  # <= this is a change
           ) -> grid (
                -row => $x, 
                -column => $y
                );
....

    [download]
    should have the -command replaced with 
               -command => sub {print "hi"}  # <= this is a change
....

    [download]

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom