You could always use a parser:

$grammar = <<'__END_OF_GRAMMAR__';

   {
      use strict;
      use warnings;
      $skip = qr/[ \t]*/;
   }

   # Returns a ref to an array of lines.
   parse : line(s?) /$/     { $item[1] }

   # Returns a ref to an array of atoms and lists.
   line  : term(s?) /\n/    { $item[1] }

   # Returns an atom or a list.
   # An atom looks like: [ atom => "text" ]
   # A list is a ref to an array of atoms and/or lists.
   term  : '{' term(s?) '}' { [ list  => $item[2] ] }
         | /[^{} \t\n]+/    { [ atom  => $item[1] ] }

__END_OF_GRAMMAR__
[download]

Update: Added missing closing square brackets.

Update: Tested:

Note: It's quite easy to modify the grammar to generate data in a different format. Let me know if you need help to do so.

I think you didn't quite get my point about reducing your code to the smallest possible program that illustrates the problem. You've got so much extraneous data (and code) that it's really hard to see what might be going wrong. It's also not clear what result you're expecting, and you didn't show what result you got. When I run your code, it tells me there are two matches, and your description seems to imply that you expect two... so I'm not even sure you have a problem.

(Aside: If you're going to use vars all your variables, and call your subroutines with &, you may as well not bother with use strict.)

Here is your question, rephrased (and trimmed down) as best I could decipher. Please clarify if I misunderstood, because this question is what I am answering below.

my @data = (
  'Line1 <error 1 1 <foo> <bar>> <three 1 1 <baz> <qux>> <fixv 1 1 qib
+ qeg>',
  'Line2 error 1 1 <foo> <bar> <three 1 1 <baz> <qux>> <fixv 1 1 qib q
+eg>',
); 
# The single match on Line2 is correct, 
# but I am only getting one match from Line1. 
# When I work the pattern by hand, 
# I see that it should match twice on Line2. 
# How can I get the second match?
foreach my $test (@data) { 
  if ($test =~ /(<[a-z]{4,5}\s\d\s\d\s<[^>]+?>\s<[^>]+?>>)/gx ) {
    print "Found '$1' in line '$test'\n";
  }
}
[download]

When you want to capture separate instances of the match multiple times in the same line you use the /g modifier, and either:

• loop over the match in scalar context, like while ( m/(\d+)/g ) {print $1};
• or capture all the matches at once in list context (to be looped over later), like @matches = m/(\d+)/g; .

Working, tested code:

use strict;
use warnings;

# Set this to 0 or 1; 
# the output will be exactly the same either way.
my $use_scalar_method = 1;

# I added the first "open inner brace", 
# so that the indentation would balance.
my $pattern = qr/
  \{           # open outer brace
    [a-z]{4,5} #   4 or 5 lowercase letters
    \s         #
    \d         #   single digit
    \s         #   
    \d         #   single digit
    \s         # 
    \{         #   open inner brace
      [^}]+?   #     everything up to the close brace
    \}         #   close inner brace
    \s         #
    \{         #   open inner brace
      [^}]+?   #     everything up to the close brace
    \}         #   close inner brace
  \}           # close outer brace
/x;
 
my @data = (
  'DataLine1 {error 1 1 {^E 0-20-9:0-50-9:0-50-9.*$} {^E 0-20-9:0-50-9
+:0-50-9.*$}} {three 1 1 {^.*35=A.*$|^.*35=5.*$} {^.*35=A.*$|^.*35=5.*
+$}} {fixv 1 1 ^.*VFIXFxProxy.*Disconnected ^.*VFIXFxProxy.*Disconnect
+ed}',
  'DataLine2 error 1 1 {^E 0-20-9:0-50-9:0-50-9.*$} {^E 0-20-9:0-50-9:
+0-50-9.*$} {three 1 1 {^.*35=A.*$|^.*35=5.*$} {^.*35=A.*$|^.*35=5.*$}
+} {fixv 1 1 ^.*VFIXFxProxy.*Disconnected ^.*VFIXFxProxy.*Disconnected
+}',
  'DataLine3 error 1 1 {^E 0-20-9:0-50-9:0-50-9.*$} {^E 0-20-9:0-50-9:
+0-50-9.*$} {twentythreeistoobig 1 1 {^.*35=A.*$|^.*35=5.*$} {^.*35=A.
+*$|^.*35=5.*$}} {fixv 1 1 ^.*VFIXFxProxy.*Disconnected ^.*VFIXFxProxy
+.*Disconnected}',
); 

my $line_number = 0;
foreach my $test (@data) { 
  $line_number++;
  print "\nLine: $line_number\n";

  if ($use_scalar_method) {
    my $match_number = 0;
    # Scalar context:
    # You can get the matches one-at-a-time this way.
    while ( $test =~ /($pattern)/g ) {
      $match_number++;
      print "Match $match_number: $1\n";
    }
    print "No matches.\n" unless $match_number;
  }
  else {
    # List context:
    # You can get all the matches at once this way.
    my @matches = ($test =~ /($pattern)/g)
      or print "No matches.\n"
      and next;
    
    my $match_number = 0;
    foreach my $match (@matches) {
      $match_number++;
      print "Match $match_number: $match\n";
    }
  }
}
[download]