use strict;
use warnings;

  my %hash = (one   => "one",
              two   => "two",
              three => "three" );

  print "$hash{one}\n";
  test();
exit;

sub test {
  for (keys %main::hash) {
   print "$_ $main::hash{$_}\n";
  }
}
[download]

my %hash does nothing to %main::hash, even if you are in package main. That is why "package variables" are also called "globals" and "my variables" are called "lexicals". Lexical variables are not in any symbol table. For example:

package one;
my $x= "hi";
package two;
print "$x\n";
# prints "hi"
[download]

This also illustrates a "feature" of our (that might be useful but could also be a source of problems):

package one;
our $x= "hi";
use vars qw($y);
$y= "lo";
package two;
print "$one::x $one::y\n"; # prints "hi lo"
print "$x\n"; # prints "hi"
print "$y\n"; # prints nothing
# and would give an error under C<use strict>
[download]

        - tye (but my friends call me "Tye")

Strict means you must declare your variables with my(), our(), or 'use vars', or use fully qualified package names. Using our() or 'use vars' is just a way of saying we want a global variable but we don't want to have to use the fully qualified name all the time -- you do not have to declare globals that way if you do use fully qualified names (as you do in your sub).

Your example has two hashes: the global %main::hash (created on the fly in your subroutine) and the lexical %hash (declared near the top with the my() statement).

No warnings are produced by your sub because the main::hash is referenced twice (no 'used only once' warning), and the print() never executes because there are no keys to loop over (no 'unitialized' warnings).