for (<*>) {
    if(/\.TMB/i) {
        $old=$_;
        s/\.TMB$/T\.JPG/;
        die "$_ already exists" if (-e $_);
        rename($old, $_) or die "Failed to rename\n";
    }
}
[download]

If you change:

    s/\.TMB$/T\.JPG/;

...to:

    s/\.TMB/T.JPG/i;

...you'll catch all cases of all cases. ;]

Meanwhile, here's a total treatment with a bit of commentary; it uses some neat grep tricks a friend taught me a while back to narrow the list of files before you start processing. I've only tested it a little but it should be correct.

Cheers!

--j

#!/usr/bin/env perl
#
# mvThumbs:
#   A quick script to move thumbnails
#

use strict;
use Cwd;

if (! @ARGV) {
  # We need arguments, durnit!
  warn "${0}: Insufficient arguments\n";
  warn "Syntax: $0 <dirName> ...\n";
  exit(1);
}

# They may give us directory paths which are relative to where we are,
# so let's be sure of where we are, eh?
my $origCWD = cwd();

foreach my $dirName (@ARGV) {
  unless (-d $dirName) {
    warn ">>> $dirName is not a directory ... skipping.\n";
  } else {
    # Can we write here? If not, we may as well skip it
    unless (-w $dirName) {
      warn ">>>> No write permissions in $dirName ... skipping\n";
    } else {
      # Get the list of thumbnails in this directory
      opendir(thumbDir, $dirName);
      my @thumbList = grep /\.TMB$/i, readdir(thumbDir);
      closedir(thumbDir);

      # To be lazy about having to construct pathnames, we'll just
      # move to the directory we're working with.
      chdir($dirName);
      print "\nIn directory: $dirName\n";

      # Run through the list and rename 'em
      foreach my $thumbFile (@thumbList) {
        my $newFile = $thumbFile;
        $newFile =~ s/\.TMB$/T.JPG/i;
        # You could force the filename into lower or upper case here
        # $newFile = lc($newFile);
        # $newFile = uc($newFile);
        unless (-e $newFile) {
          printf("%-30s => %s\n",$thumbFile, $newFile);
          rename($thumbFile, $newFile);
        } else {
          warn ">>> Can't move $thumbFile => $newFile in $dirName;\n";
          warn ">>>   $newFile already exists. Skipping.\n";
        }
      }
			
      # Back to home base for the next one
      chdir($origCWD);
    }
  }
}

print "\nAll done!\n";

Corret about the /i thing.

Also, instead of filtering out using grep, you can just glob the files that you are looking for by:

    foreach my $thumbFile (glob('*.TMB')) {...}
[download]

(I left the core like the original question, just to make it easy for the guy/gal in the original post)

Hmmm ... surely you don't actually want to 'die' in the middle of a for loop just because one of your files already happens to have the new extension?

i.e., if I had apple.TMB and apple.JPG then none of banana.TMB, pear.TMB or wombat.TMB would get renamed...

Tony

1. As the (updated) song sais: "This is my script and i'll die if i want to" :)

2. There wouldn't be a problem with your example as apple.tmp goes to applet.jpg

Anyway, just as you noticed it, I'm sure that Anonymous Monk that posted the original question will be able to adopt the script to his needs. He didn't specify what to do in such cases so better be safe than sorry.

This should do the trick for you, and should be cross platform as well (you'll all let me know won't you? ;)

#!perl -w

use File::Copy;
while (defined(my $filename = <*.tmb>)) {
    my $filename_2 = substr($filename,0,length($filename)-4)."t.jpg";
    move($filename,$filename_2);
}
[download]

personally I would use "_t.jpg" as opposed to "t.jpg" simply because I find it easier to read "pic_t.jpg" over "pict.jpg", but that's just my opinion ;)

ryddler

Depends on if you want to group your files by type (thumb|full) or picture name. I personally put these kind of indicators in front of the filename, like "th_filename.ext", or "t_filename.ext" so that they are grouped by type.

Even if they end up residing in different directories, it's easier on the eyes.

joecamel

What you can do is do a grep(/\.TMB$/, readdir(THUMBS)) which will give you the list of thumbnail files. Then make sure you don't blow away existing files during your renaming function.

Make your regex case insensitive by adding an i. See perldoc perlre or man perlre.

I think DOS can do one better though my memory of syntax may be incorrect.
C:\> move *.tmb *t.jpg
Note: this is not suggesting that DOS is better than bash in anyway, I firmly believe that DOS (and windows too, though that isn't under discussion) sucks. :)

You might want to check Rename files safely which gives the same behavior with some perlish extras.

Why even use cut, awk, or sed to trim when you could just use the shell parameter replacement "${i%TMB}JPG". But to keep it perl:

while (<*.TMB>) {
 my $new = $_;
 substr($new, -3) = "JPG";
 warn "$new already exists", next if -e $new;
 rename $_, $new or warn "Error renaming $_: $!";
}
[download]

Update: I just saw only the above node when I answered, I now see that except for my first comment on the shell solution, I've posted practically the same code already posted higher up (great minds think alike I suppose) :0)