I managed to convert the section in your example into a string in JSON notation using the following:

my $section = [ 
    [ "image1.gif" , "mark('a' ,1)" ],
    [ "image2.gif" , "mark('a' ,2)" ],
];

my $parsed = '[ ' . 
             join( ' , ', map { '[ "' . join('" , "', @$_) . '" ]' } @
+$section ) .
             ' ]';
[download]

$parsed will contain the following string:

[ [ "image1.gif" , "mark('a' ,1)" ] , [ "image2.gif" , "mark('a' ,2)" 
+] ]
[download]

which is (I think) what you want. (There's an extra square bracket in your example, which I omitted.)

It does use map, among other things, though I'm not sure it qualifies for "clean-lookin". I found a CPAN module called JSON which produced the same result more cleanly, and would probably be easier to maintain:

use JSON;

my $json = JSON->new;

my $section = [
    [ "image1.gif" , "mark('a' ,1)" ],
    [ "image2.gif" , "mark('a' ,2)" ],
];

my $parsed = $json->objToJson( $section );
[download]

I'm not sure I understand correct since the two snippets are equivalent. I'm assuming you're looking for help converting the memory structure in the first snippet into the string shown in the second snippet. This works:

sub bracket {
   local $_ = @_ ? $_[0] : $_;
   return "[ $_ ]";
}

sub quote {
   local $_ = @_ ? $_[0] : $_;
   s/(["\\])/\\$1/g;
   return qq{"$_"};
}

@{$_[0]->{'images'}{'section_a'}} = (
   [ "image1.gif" , "mark('a',1)" ],
   [ "image2.gif" , "mark('a',2)" ],
);

print(
   bracket            # Put brackets around the row.
   join ',',          # Join the records.
   map {              # For each record,
      bracket         #    Put brackets around each record.
      join ',',       #    Join the fields.
      map quote, @$_  #    Quote and escape the fields.
   } @{$_[0]->{'images'}{'section_a'}}
);

__END__
output
======
[ [ "image1.gif","mark('a',1)" ],[ "image2.gif","mark('a',2)" ] ]
[download]

You may want to use Data::Dumper instead.

my @foo = ([qw(one two)], [qw(three four)], [qw(five six)]);
# use List::Util 'reduce';
# oops: my $str = reduce {"[$a,$b]"} map { reduce {"[$a,$b]"} @$_ } @f
+oo;
my $str = sprintf "[%s]", join ',', map { sprintf '["%s"]', join '","'
+, @$_} @foo;
print "--- $str ---\n";
[download]

#!/usr/bin/perl -w
use strict;

my @foo = ([qw(one two)], [qw(three four)], [qw(five six)]);
use List::Util 'reduce';

my $str = reduce {"[$a,$b]"} map { reduce {"[$a,$b]"} @$_ } @foo;
print "--- $str ---\n";

my $seen = 0;
$str = reduce { $seen++ ? $a.",[$$b[0],$$b[1]]"
                        : "[$$a[0],$$a[1]],[$$b[0],$$b[1]]"
              } @foo;

print "--- [$str] ---\n";
[download]

use Data::Dumper;
($str) = Dumper(\@foo) =~ /=(.*);$/s;
$str =~ tr/' \n/"/d;
[download]

What's wrong with using JSON to convert data from and to JSON notation?