There are several problems here. First I'll address the big one. You really REALLY don't want to do what you think you want to do. What you are trying to do is use symbolic references. What you should do is be happy with the hash. You know, the global symbol table itself is a glorified hash too. If Perl thinks a hash is good enough for it, a hash should be good enough for you too. Don't initialize global values based on symbolic references. What if the file contained some variable name that you hadn't planned for, or one that you were using for something else? You would have a difficult to track down bug.

The second problem is related to the first one. Symbolic references can only be used on package globals, but you've declared $step1, $step2, and $step3 to be lexical variables. That won't prevent you from initializing package globals of the same name, by the way. Imagine the confusion of having both lexicals and package globals with the same name! You're headed down that road.

The third problem is that your $key = $value assignment simply clobbers the symbol name held in $key, it doesn't assign anything to the package global variable of that name. You can learn how to do this if you dive into the Camel book or Perl's POD, but that would mean learning how to manipulate symbolic references, which you shouldn't be doing anyway. ;)

The fourth problem is this line:

while ($line ne ""){
        chomp($line);
[download]

$line will never equal "". That's because it will always at least contain a "\n" newline character, except possibly for the last line. chomp first, and then test. Here's the cannonical way to do it:

while ( $line = <FILE> ) {
    chomp $line;
    next if $line eq "";
    #...... do your stuff here
} # end of while loop.
[download]

The biggest point to be made here is that instead of trying to initialize $step1, $step2, and $step3, you should be initializing $hash{step1}, $hash{step2}, and so on. Just say no to symbolic refs.

#!/usr/bin/perl
[download]

no strict;  # Yuk!  
no warnings;  # Yuk!
# s/no/use/gsm;
[download]

my $step1;
my $step2;
my $step3;
my @array1;
my @array;
my $i = 0;
[download]

• Avoid predeclaring long lists of variables,
• don't do this, use a hash, instead!

open(FILE, "assign");
[download]

open my $fh, '<', 'assign' or
  die "hard, but say why (\$!): $!\n";
[download]

$line = <FILE>;
while ($line ne ""){
[download]

while (<$fh>) { ... # or
while (my $line=<$fh>) { ...
[download]

        chomp($line);
        if($line =~ /^(\S+)\s+(\d+)$/) {
                print "inside\n";
                $hash{$1} = $2;
[download]

                $i++;
[download]

while( ($key, $value) = each %hash) {
        print "$key +> $value\n";
        $key = $value;
}
[download]

Proof of concept:

#!/usr/bin/perl -ln

use strict;
use warnings;

BEGIN { @ARGV='assign' }

our %hash;
$hash{$1}=$2 if /^(\S+)\s+(\d+)/;

END {
    my @msg=qw/FOO 1st 2nd 3rd/;
    $hash{"\$step$_"} and print $msg[$_] for 1..3;
}

__END__
[download]

which if are you talking about?

#!/usr/bin/perl -w
use strict;

my $line = <DATA>;
my %hash = ();

while ($line) { # and $line ne ""){
        chomp($line);
        if($line =~ /^(\S+)\s+(\d+)$/) {
                print "inside\n";
                $hash{$1} = $2;
        }
        $line = <DATA>;
}

print +($_ , " -> ", $hash{$_},$/) for (keys %hash);
__DATA__
$step1 1
$step2 1
$step3 1
[download]

Output

inside
inside
inside
$step2 -> 1
$step3 -> 1
$step1 -> 1
[download]

Are you sure the data does not contain leading spaces?

UPDATE:corrected a type, I meant hash, not bash!

Hi,

It's doable, but, please read the other comments first: it's a whole lot better to stick with a hash!

#!/usr/bin/perl

use strict;
use warnings;

# but you really don't want to do this
# stick with a hash!

# here we have 3 vars, but what if if there's more than 3?
my ($step1,$step2,$step3);

while (<DATA>) {
    my $line = $_;
    chomp $line;
    my ($var,$val) = split / /, $line;
    eval "$var=$val";
}
# here we have 3 vars, but what if if there's more than 3?
print $step1 . "\n";
print $step2 . "\n";
print $step3 . "\n";

__DATA__
$step1 1
$step2 1
$step3 1
[download]