I think you've created some tangled spaghetti code, here, with your uses of next. I suggest you use if-else blocks.

Your "port-channel" regexp sucked away matches for "interface port-channel", change the first regexp to "^port-channel" should resolve the regexp issue. Also why not use a more decent and easy to uderstand if-elsif structure.

use strict;
use warnings;

# $/="*\n"; 

my ($Rec,$pc_name);
my ($hash,$key);


while (<DATA>) 
{
    if (/^port-channel (\d+)$/) {
        $pc_name = $1;
    } elsif (m|(fc\d+/\d+)\s+\[(\w+)\]|) {
        $Rec->{$pc_name}->{$1} = $2;
    } elsif (/interface port-channel (\d+)/) {
        $key = $1;
    } elsif (/switchport description To (\w+) ([\d\.]+)/) {
        $hash->{$key}->{$1} = $2;
    }
}

for my $data (keys %{$Rec}) 
{
   print "\nPort-Channel $data : \n";
   for my $data2 (keys %{$Rec->{$data}})
   {
      print "\t$data2\n";
   }      
}

for my $data (keys %{$hash}) 
{
   print "\nInterface Port-Channel $data : \n";
   for my $data2 (keys %{$hash->{$data}})
   {
      print "\t$data2\n";
   }      
}
     

__DATA__
port-channel 1
    Administrative channel mode is on
    Operational channel mode is on
    Last membership update succeeded
    First operational port is fc1/5
    2 ports in total, 2 ports up
    Ports:   fc2/5    [up]  
             fc1/5    [up] *

port-channel 3
    Administrative channel mode is on
    Operational channel mode is on
    Last membership update succeeded
    First operational port is fc1/1
    1 port in total, 1 port up
    Ports:   fc1/1    [up] *

interface port-channel 1
  switchport trunk allowed vsan 1000
  switchport trunk allowed vsan add 1050
  switchport description To CCC219 10.33.81.56
  switchport mode E

interface port-channel 3
  switchport trunk allowed vsan 1000
  switchport trunk allowed vsan add 1010
  switchport trunk allowed vsan add 1050
  switchport trunk allowed vsan add 1900
  switchport description To CCC215 10.33.81.52
  switchport mode E
[download]

Looks like $pc_name isn't getting its assignment when you think it should be. I modified to debug like this:

while (<DATA>)
{
    $pc_name = $1, next if (/port-channel (\d+)$/); #line 14
    if (m|(fc\d+/\d+)\s+\[(\w+)\]|)  {
            print "dbg: \$pc_name:'$pc_name' \$1:'$1' \$2'$2'\n";
            $Rec->{$pc_name}->{$1} = $2;
   }
    $key = $1, next if (/interface port-channel (\d+)$/); # line 17
    $hash->{$key}->{$1} = $2 if (/switchport description To (\w+) ([\d
+\.]+)/); #line 18
}
[download]

And the 'dbg' print to STDOUT shows that $pc_name isn't populated. I think that's your undefined key. (At least that's what seems broken to me.)

It's not my style, but I don't like that comma-next construct. It may be valid, but I'm not personally sure how it parses, so I wouldn't use it. Take Roy_Johnson's advice and restructure and I'll bet it works out just fine...

As Roy Johnson correctly said, your first regex matches the same lines, your third matches. This doesn't happen, if you anchor the regex with /^.../ for the start of the line.

I would also do it like this to not match the second regex,when it's not appropriate:

  if (my $hit= /^port-channel (\d+)$/ .. /^\s*$/) {
    if ($hit == 1) {
      $pc_name = $1;
      next;
    }
    $Rec->{$pc_name}->{$1} = $2 if (m|(fc\d+/\d+)\s+\[(\w+)\]|); #line
+ 15    
  }
  elsif (my $hit= /^interface port-channel (\d+)$/ .. /^\s*$/) { 
    if ($hit == 1){
      $key = $1;
      next;
    }
    $hash->{$key}->{$1} = $2 if (/switchport description To (\w+) ([\d
+\.]+)/); #line 18
  }
[download]

I feel a donation is coming up,....thanks for putting me out of my misery :-)


Blackadder

When you run a regex, and it assigns things to $1, $2 etc, its best to copy those into other variables right away, before you do any more regexes. There is no guarantee that they will contain the same content after running another regex, in fact its generally guaranteed that they won't.

C.