There are a number of ways you could go about this. The first, and least recommended is to use a regex something like this:

use strict;
use warnings;

#throw away first two lines
<DATA>;
<DATA>;

while (<DATA>)
  {
  chomp;
  next if ! defined $_ or ! length $_;
  my ($date, $time, $recip, $subject, $send) =
    /\s*([^\t]+)      #date
      \s+([^\t]+)     #time
      (?:\t[^\t]+){5}\s+  #Skip 5 fields
      (\S+)           #Recipient
      (?:\t[^\t]+){10}\s+  #Skip 10 fields
      ([^\t]*)\t      #subject
      ([^\t]*)        #Sender
    /x;
  
  print "$date, $time, $recip, $subject, $send\n";
  }
[download]

which generates

2005-9-10, 0:0:16 GMT, Someoneg@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, EX:/O=org/OU=Site/CN=RECIPIENTS/CN=Auser
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name
[download]

However using a regex for parsing csv data such as this can be very difficult due to managing quoted data. It is generally better to use something like Text::CSV::Simple.

Yet another option, if you are comfortable with databases, is to use DBI to wrap your file and manage it as a database.

Text::CSV::Simple is a little too simple, without making it complicated, to do the job for large files. Below is version using Text::CSV_XS.

use strict;
use warnings 'all';
use Text::CSV_XS;

my $parser = Text::CSV_XS->new ({sep_char => "\t"});

while (<DATA>)
  {
  next if ! length $_;

  if (! $parser->parse ($_))
    {
    warn "Error parsing: $_";
    next;
    }

  my @columns = $parser->fields();
  next if ! defined $columns[19];
  print "$columns[0], $columns[1], $columns[7], $columns[18], $columns
+[19]\n";
  }
[download]

Prints:

# Date, Time, Recipient-Address, Message-Subject, Sender-Address
2005-9-10, 0:0:16 GMT, Someoneg@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, EX:/O=org/OU=Site/CN=RECIPIENTS/CN=Auser
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name
[download]

Here is how I modified the script to do what I need.

use strict;
use warnings 'all';
use Text::CSV_XS;
open STDIN,"c:\\scripts\\20051030.log" or die $!;

 my $columns;

open STDOUT, ">Answers.out" or die "can't redirect stdout";

my $parser = Text::CSV_XS->new ({sep_char => "\t"});

while (<STDIN>)
  {
  next if ! length $_;

  if (! $parser->parse ($_))
    {
    warn "Error parsing: $_";
    next;
    }

  my @columns = $parser->fields();
  next if ! defined $columns[20];
  print "$columns[0], $columns[1], $columns[7], $columns[18], $columns
[19]\n";
  }
[download]

I get this in return... Use of uninitialized value in concatenation (.) or string at C:\scripts\Xsv.pl l ine 26, <STDIN> line 392. I still not know where I put in what I am searching for. and I need to search two fields "Recipient-Address, Sender-Address" If my search word "Auser" (case should not matter)is in either field the give me the 5 columns

Are you setting the correct seperator character in Text::CSV_XS->new ({sep_char => "\t"});?

---

Perl is Huffman encoded by design.

Add use Data::Dumper; and update your next if ! defined $columns[20]; line to (print Dumper (\@columns)), next if ! defined $columns[20]; to see what is actually in @columns.

---

Perl is Huffman encoded by design.

What does the debugger tell you is undefined?

Alex / talexb / Toronto

"Groklaw is the open-source mentality applied to legal research" ~ Linus Torvalds

I think you want something like this:

#!/usr/bin/perl -w
use strict;
use Text::CSV_XS;
use IO::File;

my $filename          = 'hdi.csv';
my $column_to_search  = 1;
my $wanted_value      = 'Sweden';

my $csv = Text::CSV_XS->new({binary=>1});
my $fh = IO::File->new($filename) or die $!;
while (my $cols = $csv->getline($fh)) {
    last unless @$cols;
    next unless defined $cols->[$column_to_search]
            and $cols->[$column_to_search] eq $wanted_value;
    for (0,1,3) {
        $cols->[$_] = '' unless defined $cols->[$_];
    }
    print join(' ',$cols->[0],$cols->[1],$cols->[3]),"\n";
}
[download]

and to complete the suite - a version using DBI. Note that there is a "cheat" here in that the first line of the sample data has been omitted and, due to the # at the start of the header line the data field's name is '# Date'.

use strict;
use warnings 'all';
use DBI;

# Create the sample file
open outFile, '>', 'sample.csv';
print outFile
[download]

';
close outFile;

# The real sample code
my $dbh = DBI->connect(qq{DBI:CSV:csv_sep_char=\\\t})
    or die "Cannot connect: " . $DBI::errstr;
my $sth = $dbh->{'csv_tables'}->{'info'} = { 'file' => 'sample.csv'};
$sth = $dbh->prepare("SELECT * FROM sample.csv")
    or die "Cannot prepare: " . $dbh->errstr();
$sth->execute() or die "Cannot execute: " . $sth->errstr();
while (my $row = $sth->fetchrow_hashref)
  {
  print("$row->{'Date'}, $row->{'Time'}, $row->{'Recipient-Address'}, 
+$row->{'Message-Subject'}, $row->{'Sender-Address'}, \n");
  }

$sth->finish();
$dbh->disconnect();
[download]

Prints:

2005-9-10, 0:0:16 GMT, Someoneg@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, EX:/O=org/OU=Site/CN=RECIPIENTS/CN=Auser, 
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -, 
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -, 
2005-9-10, 0:0:16 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, -, 
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name, 
2005-9-10, 0:0:17 GMT, c1r3ai4g@aol.com, Fw: Hey Ugly line expansion a
+nd re-offer, Auser@Domain.name,
[download]

my $sth = $dbh->{'csv_tables'}->{'info'} = { 'file' => 'sample.csv'};
$sth = $dbh->prepare("SELECT * FROM sample.csv")

The "my $sth =" on the first line is wrong. And the SQL in the second line should be either q{SELECT * FROM "sample.csv"} or q{SELECT * FROM info}. The first uses quotes to delimit the table name (thus allowing the forbidden period) and the second skirts the issue by using the alias to the filename you created with csv_tables.

awk -F"\t" '/Auser/ { print $1, $2, $8, $20 }' file.txt
[download]

Wouldn't it have been better to just show the op the Perl version?

I believe it comes out something like this :-

while (<>) {
    my @Fld = split('\t', $_);
    if (/Auser/) {
        print $Fld[0], $Fld[1], $Fld[7], $Fld[19];
    }
}
[download]