You can remove the periods from a copy before testing (with tr/.//d), or else construct a regex with optional periods:

my $to_match = 'xyz123abc';
$to_match = join '\.*', map {quotemeta} split //, $to_match;
# $to_match is now 'x\.*y\.*z\.*1\.*2\.*3\.*a\.*b\.*c'.

$to_match = qr/$to_match/;

/$to_match/ && print for <>;
[download]

How about storing each line in a temporary variable, removing periods from that and then matching against the resulting string? e.g.

@matches=( qr/match1/,
           qr/match2/, ...);
open ($file,"<","/path/to/file") or die ("Horribly");

while (<$file>) {
  $temp=$_;
  $temp=~s/\.//g;
  for my $match (@matches) {
    if ($temp =~m/$match/) {
      do_something();
    }
  }
}
[download]

If you're only going to match against one value you're probably better off adjusting that value (e.g.

), but if you have multiple matches(and possibly multiple ignorable characters) the first suggestion should work well for you.

#! /usr/bin/perl 
use strict;
use warnings;

my $lookfor = "xyz123abc";
while (<DATA>) {
    chomp;
    print "$_ matched\n" if join('', /([^\.]+)/g) =~ /^$lookfor$/;
}

__DATA__
xyz123abc
xy.z123abc
xyz1.23.abc
xyz123abc1
[download]

Hi, if i understood your question correctly, this will help you.

my $str="xy.z123abc xyz1.23.abc";
while ($str=~m/[\w\.]+/gsi)
{
    print $&, "\n";
}
[download]

Updated: This won't work, i misunderstood the question. Sorry...

open my $fh, "<filename" or die "$!, for filename";
my $found = 0;
while( <$fh> ) {
    my $tmp = $_;
    $tmp =~ s/\.//g;
    $found = ( $tmp =~ /xyz123abc/ ) and last;
}
close $fh;
if ( $found ) {
    # etc.
}
[download]