$HoA{$rboc}{$telco}++; is fine, except it's a HoH, not a HoA. It's a shortcut for

$HoA{$rboc} = {} unless defined $HoA{$rboc};
my $anon_temp = $HoA{$rboc};
$anon_temp->{$telco}++
[download]

$HoA{$rboc, $telco}++;
also works, but it means
$HoA{join($;, $rboc, $telco)}++;
which is probably not what you want.

Update: s/unless exists/unless defined/

That's fine, but it is a Hash of Hash (HoH), not a Hash of Array (HoA). You should perhaps take a look at Data::Dumper.

use strict;
use warnings;
use Data::Dumper;

my $rboc    = "SA";
my $telco   = "0009";
my %HoH;
my %MultiHash;

$HoH{$rboc}{$telco} ++;
$MultiHash{$rboc, $telco} ++;

print Dumper (\%HoH);
print Dumper (\%MultiHash);
[download]

Prints:

$VAR1 = {
          'SA' => {
                    '0009' => 1
                  }
        };
$VAR1 = {
          'SA0009' => 1
        };
[download]

Note that there is a hidden character in the 'SA0009' string!

Update: added second method.

thanks to all who answered so QUICKLY! the HoA business was carelessness...sorry. regards, Barry

The only comment is that it's not a HoA, it's a HoH.

The datastructure will look like this:

%HoH = (
    SA => {
        0009 => 1
    }
);
[download]

It's done that way all the time. Your second method: $HoA{$robc,$telco} will work but not in the same way (ie, it's not a hash of hashes anymore). IMHO, it's probably better to use a HoH instead of a hash with some multi-part key.

or perhaps $HoA{$rboc,$telco} ++; I've never seen this in any literature but it seems to work OK...comments?

My first thought is "what are you trying to accomplish? "

Consider the following:

#!/usr/bin/perl -w
######################################################################
+##
 
 
use strict;
use Data::Dumper;
 
 
my %hash=();
 
 
foreach my $i('a'...'g'){
    foreach my $j('a'..'g'){
        $hash{$i,$j}="-";
    }
}
 
 
 
print Dumper(%hash);
[download]

When run produces:

Was this what you were after?

I noticed that GrandFather showed the other method. It is all in what you want to accomplish...

The data will be organized betted if you substitue
print Dumper(%hash);
with
print Dumper(\%hash);

The data will be organized betted if you substitue

True

Done that way it looks like:

$VAR1 = {
          'dd' => '-',
          'fb' => '-',
          'ab' => '-',
          'ge' => '-',
          'bd' => '-',
          'dc' => '-',
          'aa' => '-',
          'cc' => '-',
          'ae' => '-',
          'ba' => '-',
          'cb' => '-',
          'gb' => '-',
          'ef' => '-',
          'ea' => '-',
          'gd' => '-',
          'ec' => '-',
          'cg' => '-',
          'ad' => '-',
          'eg' => '-',
          'de' => '-',
          'fe' => '-',
          'fg' => '-',
          'dg' => '-',
          'cf' => '-',
          'bf' => '-',
          'ed' => '-',
          'ce' => '-',
          'ac' => '-',
          'gf' => '-',
          'bb' => '-',
          'db' => '-',
          'ee' => '-',
          'bc' => '-',
          'ga' => '-',
          'gc' => '-',
          'af' => '-',
          'fd' => '-',
          'gg' => '-',
          'fc' => '-',
          'ca' => '-',
          'ag' => '-',
          'be' => '-',
          'fa' => '-',
          'cd' => '-',
          'ff' => '-',
          'bg' => '-',
          'df' => '-',
          'da' => '-',
          'eb' => '-'
        };
[download]

Much more readable.

I've never seen this in any literature

Then you have yet to read perldoc perldsc the "Perl Data Structures Cookbook". If you are just venturing into using more complicated data structures, this would probably be a really good time to check it out.

-sauoq
"My two cents aren't worth a dime.";