Hi all, I want pass a hash to subroutine, is that possible

Yes. Usually you would just pass a reference.

sub myfunc {
    my $href = shift; 
    print $href->{foo}, "\n";
}

my %h = ( foo => 'bar' );

myfunc(\%h);
[download]

It is possible to pass the whole hash but it gets messy if you want to add arguments later. Some people handle named parameters this way. (Others prefer a hash ref for that too.)

sub myfunc {
    my %hash = @_; 
    print $hash{foo}, "\n";
}
my %h = ( foo => 'bar' );
myfunc(%hash);
myfunc( foo => 'baz' );
[download]

There is one significant difference between these you should be aware of. In the first example, you are passing a reference to the hash itself. If you would change the hash via the reference within your sub, you would see those changes outside of your sub. In the second example, the line my %hash = @_; makes a copy of the hash. Changes to that copy inside the sub will not be seen outside of the sub. On the other hand, if you have a large hash, making a copy might take a lot of resources.

Edit: Added quote from OP.

-sauoq
"My two cents aren't worth a dime.";

#! perl -w

%a = (qw{ 
good orange
good apple}
);

TEST(%a);
sub TEST{
my %h = @_;
foreach (keys %h){
    print $_;
}
}
[download]

Note using @_ where you had used $_[0] - that converts the entire array of parameters into a hash.

This is because the function receives a list of param, value, param, value.., which is stored in @_. By doing %h = @_; you put this into a hash with the first, third, fifth etc values as keys, and the second, fourth, sixth etc as values.

Thanks for all "rapid" reply, the case solved

But once more, if i want pass 2 or more hashes to subroutine, is it the same?

If you want to pass 2 or more hashes to a subroutine, you really need to use references. Have a look at perldoc perlref, but basically the syntax is:

my %hashA = ( orange=>'good',
              apple=>'bad' );

my %hashB = ( here=>'today',
              gone=>'tomorrow' );

myfunction(\%hashA,\%hashB); # send references to the hashes

sub myfunction
{
  my $hashrefA = shift; # (or $_[0])
  my $hashrefB = shift; # (or $_[1])

  my %hashA = %$hashrefA; # treat the refs as hashes and
  my %hashB = %$hashrefB; # copy the contents

  $hashA{extravalue} = "change seen in the subroutine only";
  $hashrefA->{extravalue} = "change seen in the main program";

}
[download]

Following on from sauoqs comments, with that syntax, %hashA and %hashB in the subroutine are still copies of the original hashes. If you want to manipulate the original hashes and have the changes seen by the main part of the program, you will have to manipulate the hashrefs. I've included an example of each in the snippet above. If all you want to do is e.g. print them out, the copies might be less unwieldy to work with, if you're not familiar with reference syntax.

--------------------------------------------------------------

"If there is such a phenomenon as absolute evil, it consists in treating another human being as a thing."

John Brunner, "The Shockwave Rider".

But once more, if i want pass 2 or more hashes to subroutine, is it the same?

It was already in my answer, (although I minimally updated it silently for added clarity). Minimal example using a prototype:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

sub foo (\%\%) {
    Dumper @_;
}

my %a=(foo => 1, bar =>2);
my %b=(%a, bax => 3);
print foo %a, %b;

__END__
[download]

Yes, it's possible. But it depends on what you actually want to do. If you just want to do what you show in your example, then

my %h=@_;  # is enough!
[download]

But if you also want to modify the hash you pass in, or if you want to pass a few params of which one (or more) happens (happen) to be a hash, then as others already pointed out, you have to use a reference. You can also use a prototype, as explained in perldoc perlsub to have perl doing this for you. But regard that as a somewhat advanced technique and be sure to have understood the docs if you want to apply it...