in reply to Re^2: Dynamic population of a hash
in thread Dynamic population of a hash

You can use split to split the path up on the slashes, like so: 
my @values = split m:/:, $path_string;

[download]
It's not at all clear why you'd be putting that into a hash as you illustrate. It would be more interesting to make a multilevel hash that mimics the hierarchy of a list of paths: 
my $hashed_path = {};
for my $path_string (@list_of_paths) {
  my $hpref = $hashed_path;
  for $dir (split m:/:, $path_string) {
    $hpref->{$dir} = {} unless exists $hpref->{$dir};
    $hpref = $hpref->{$dir};
  }
}

[download]
That might be a bit much to absorb so early in your Perl experience, but maybe not.
Caution: Contents may have been coded under pressure.

Replies are listed 'Best First'.
Re^4: Dynamic population of a hash
by Anonymous Monk on Nov 09, 2005 at 15:12 UTC

    Thanks everyone. A more concise code sample would be nice, but unfortunately I cannot place this in the public view, so anything I can put out there is gutted etc....But I'll be more attentive when I post other questions and try to make it more complete.

    Could you explain the my $hashed_path={}. Is this some sort of Perl initialization for a variable?

    In my ignorance, how does this make a multilevel hash? I don't see the hast operator in the sample. I understand that PERL does some magic behind the scenes, is this one of those cases?

[reply]
      {} is an empty hash reference. I could have started with an empty hash, which might have been a little easier to understand, and I should have annotated my code. So I'll do that here: 
      # Read in my list of paths and cut off the newlines
my @list_of_paths = <DATA>;
chomp @list_of_paths;

my %hashed_path = ();
for my $path_string (@list_of_paths) {
  # This tracks our descent in the path tree. We start at the top
  my $hpref = \%hashed_path;
  # Split the path into its component directories, and walk through th
+em
  for my $dir (split m:/:, $path_string) {
    # At each level, if we've never been there before, create an entry
+ for it
    $hpref->{$dir} = {} unless exists $hpref->{$dir};
    # Then descend into it so we're ready to insert the next level
    $hpref = $hpref->{$dir};
  }
}

# See what the structure looks like
use Data::Dumper;
print Dumper \%hashed_path;
__DATA__
/top/middle/bottom
/top/middle/newleaf
/top/new_middle/bottom

      [download]
      Output is 
      $VAR1 = {
          '' => {
                  'top' => {
                             'middle' => {
                                           'newleaf' => {},
                                           'bottom' => {}
                                         },
                             'new_middle' => {
                                               'bottom' => {}
                                             }
                           }
                }
        };

      [download]
      The topmost level has only the key of empty string because that's the first value in a split on '/' when the string starts with '/'.
      Caution: Contents may have been coded under pressure.
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom